kde-base/poxml/poxml-4.14.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/poxml/poxml-4.14.3.ebuild,v 1.4 2015/02/16 08:31:42 ago Exp $

EAPI=5

JAVA_PKG_OPT_USE=extras
inherit java-pkg-opt-2 java-ant-2 kde4-base

DESCRIPTION="KDE utility to translate DocBook XML files using gettext po files"
KEYWORDS="amd64 ~arm ppc ~ppc64 x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="debug extras"

DEPEND="
	extras? (
		>=virtual/jdk-1.5
		>=dev-java/antlr-2.7.7:0[cxx,java,script]
	)
"
RDEPEND="
	extras? (
		>=virtual/jre-1.5
		>=dev-java/antlr-2.7.7:0[cxx,java,script]
	)
	!<=kde-base/kdesdk-misc-4.10.50:4
"

# java deps on anltr cant be properly explained to cmake deps
# needs to be run in one thread
MAKEOPTS+=" -j1"

pkg_setup() {
	kde4-base_pkg_setup
	java-pkg-opt-2_pkg_setup
}

src_prepare() {
	kde4-base_src_prepare
	java-pkg-opt-2_src_prepare
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_with extras Antlr2)
	)

	kde4-base_src_configure
	java-ant-2_src_configure
}

pkg_preinst() {
	kde4-base_pkg_preinst
	java-pkg-2_pkg_preinst
}