dev-ruby/sass/sass-3.1.19.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/sass/sass-3.1.19.ebuild,v 1.1 2012/06/25 17:46:48 graaff Exp $

EAPI=2

USE_RUBY="ruby18 ruby19 ree18 jruby"

RUBY_FAKEGEM_TASK_DOC=""
RUBY_FAKEGEM_DOCDIR="doc"
RUBY_FAKEGEM_EXTRADOC="README.md"

RUBY_FAKEGEM_EXTRAINSTALL="rails init.rb VERSION VERSION_NAME"

inherit ruby-fakegem

DESCRIPTION="An extension of CSS3, adding nested rules, variables, mixins, selector inheritance, and more."
HOMEPAGE="http://sass-lang.com/"
LICENSE="MIT"

KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x64-macos"
SLOT="0"
IUSE=""

ruby_add_bdepend "doc? ( >=dev-ruby/yard-0.5.3 >=dev-ruby/maruku-0.5.9 )"

ruby_add_rdepend "dev-ruby/fssm !!<dev-ruby/haml-3.1"

# tests could use `less` if we had it

each_ruby_prepare() {
	case ${RUBY} in
		*jruby)
			# tests fail with JRuby, and that's a given for now; it's
			# not a bug in the code as much as it is relying on a detail
			# of the implementation of CRuby. We remove failing files
			# for now, this could probably be narrowed down more so that
			# we could run more tests.
			rm test/sass/script_test.rb test/sass/util_test.rb test/sass/engine_test.rb test/sass/scss/scss_test.rb || die
			;;
		*)
			;;
	esac
}