dev-python/qscintilla-python/qscintilla-python-2.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/qscintilla-python/qscintilla-python-2.1.ebuild,v 1.2 2007/11/21 22:34:38 hawking Exp $

inherit eutils python

MY_PN="qscintilla"
SCINTILLA_VER="1.73"
MY_P="${MY_PN/qs/QS}-${SCINTILLA_VER}-gpl-${PV}"

DESCRIPTION="Python bindings for Qscintilla"
HOMEPAGE="http://www.riverbankcomputing.co.uk/qscintilla/"
SRC_URI="http://www.riverbankcomputing.com/Downloads/QScintilla2/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="qt4"

DEPEND=">=dev-python/sip-4.4
	=x11-libs/qscintilla-${PV}*
	!<x11-libs/qscintilla-2.1-r1
	qt4? ( dev-python/PyQt4 )
	!qt4? ( dev-python/PyQt )"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${MY_P}/Python

pkg_setup() {
	# this package needs to have same qt flags with qscintilla.
	if use qt4; then
		if ! built_with_use 'x11-libs/qscintilla' 'qt4'; then
			eerror "Please build qscintilla with qt4 useflag."
			die "qscintilla built without qt4."
		fi
	else
		if built_with_use 'x11-libs/qscintilla' 'qt4'; then
			eerror "Please build qscintilla without qt4 useflag."
			die "qscintilla built with qt4"
		fi
	fi
}

src_compile() {
	local myconf="-o /usr/lib -n /usr/include"
	if use qt4; then
		myconf="${myconf} -p 4"
	else
		myconf="${myconf} -p 3"
	fi

	python_version
	${python} configure.py ${myconf} || die "configure.py failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
}