app-pda/gnome-pilot/gnome-pilot-2.32.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-pda/gnome-pilot/gnome-pilot-2.32.0.ebuild,v 1.6 2011/03/22 18:47:04 ranger Exp $

EAPI="3"
G2CONF_DEBUG="no"

inherit gnome2

DESCRIPTION="Gnome Palm Pilot and Palm OS Device Syncing Library"
HOMEPAGE="http://live.gnome.org/GnomePilot"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc ~sparc x86"
IUSE="eds hal"

RDEPEND="
	|| ( gnome-base/gnome-panel[bonobo] <gnome-base/gnome-panel-2.32 )
	>=gnome-base/gconf-2
	dev-libs/libxml2
	>=app-pda/pilot-link-0.11.7
	>=x11-libs/gtk+-2.13:2
	>=dev-libs/dbus-glib-0.74

	eds? ( >=gnome-extra/evolution-data-server-2 )
	hal? ( >=sys-apps/hal-0.5.4 )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext
	>=dev-util/gob-2.0.5
	>=dev-lang/perl-5.6
	>=app-text/scrollkeeper-0.3.14
	>=dev-util/intltool-0.35.5"

pkg_setup() {
	DOCS="AUTHORS COPYING* ChangeLog README NEWS"
	G2CONF="${G2CONF}
		--disable-static
		$(use_enable eds eds-conduits)
		$(use_with hal)"
}

src_install() {
	gnome2_src_install
	find "${ED}"/usr/$(get_libdir)/${PN}/conduits -name "*.la" -delete || die
}

pkg_postinst() {
	if ! has_version "app-pda/pilot-link[bluetooth]"; then
		elog "if you want bluetooth support, please rebuild app-pda/pilot-link"
		elog "echo 'app-pda/pilot-link bluetooth >> /etc/portage/package.use"
	fi
}