app-emacs/auctex/auctex-11.14.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emacs/auctex/auctex-11.14.ebuild,v 1.11 2004/05/11 03:45:34 weeve Exp $

inherit elisp

IUSE=""

DESCRIPTION="AUC TeX is an extensible package that supports writing and formatting TeX files"
HOMEPAGE="http://www.gnu.org/software/auctex"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ~ppc ~amd64 ~sparc"

DEPEND=">=sys-apps/sed-4
	virtual/emacs
	virtual/tetex"

src_unpack() {
	unpack ${A}
	sed -i 's,/usr/local/lib/texmf/tex/,/usr/share/texmf/tex/,g' ${S}/tex.el || die
}

src_compile() {
	make || die
	cd doc
	sed -i "/^auctex/s/\(-.\)/\.info\1/g" auctex
	for i in auctex* ; do
		mv $i auctex.info${i#auctex}
	done
}

src_install() {
	dodir ${SITELISP}/${PN}
	make lispdir=${D}${SITELISP} install install-contrib || die
	dosed ${SITELISP}/tex-site.el || die
	doinfo doc/auctex*
	elisp-site-file-install ${FILESDIR}/50auctex-gentoo.el
	dodoc ChangeLog CHANGES COPYING INSTALLATION PROBLEMS README
}

pkg_postinst() {
	elisp-site-regen

	if ! grep ' Xaw3d' /var/db/pkg/app-editors/emacs*/USE >/dev/null 2>&1 ; then
		ewarn
		ewarn "Emacs needs to be compiled with Xaw3d support to use the command menu."
		ewarn
	fi
}

pkg_postrm() {
	elisp-site-regen
}