app-editors/gedit-plugins/gedit-plugins-2.30.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit-plugins/gedit-plugins-2.30.0.ebuild,v 1.5 2011/04/16 20:01:14 arfrever Exp $

EAPI="3"
GCONF_DEBUG="no"
PYTHON_DEPEND="session? 2"
PYTHON_USE_WITH_OPT="session? xml"

inherit gnome2 multilib python eutils

DESCRIPTION="Offical plugins for gedit."
HOMEPAGE="http://live.gnome.org/GeditPlugins"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"

IUSE="bookmarks +bracketcompletion charmap colorpicker +drawspaces +joinlines python +session showtabbar smartspaces terminal"

RDEPEND=">=x11-libs/gtk+-2.14:2
		gnome-base/gconf
		>=x11-libs/gtksourceview-2.6:2.0
		>=app-editors/gedit-2.29.3[python]
		>=dev-python/pygtk-2.14:2
		charmap? (
			>=gnome-extra/gucharmap-2.24.3
		)
		python? (
			>=dev-python/pygtksourceview-2.2:2
		)
		terminal? (
			dev-python/gconf-python
			>=x11-libs/vte-0.19.4:0[python]
		)"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-util/intltool"

DOCS="AUTHORS NEWS ChangeLog*"

pkg_setup() {
	local myplugins="codecomment"

	for plugin in ${IUSE/python}; do
		if use session && [ "${plugin/+}" = "session" ]; then
			myplugins="${myplugins},sessionsaver"
		elif use ${plugin/+}; then
			myplugins="${myplugins},${plugin/+}"
		fi
	done

	G2CONF="${G2CONF}
		--disable-dependency-tracking
		--with-plugins=${myplugins}
		$(use_enable python)"

	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	gnome2_src_prepare

	# Fix issues with find/replace in selections
	epatch "${FILESDIR}/${P}-find-replace.patch"

	# Add Ctrl+Shift+C/V copy paste accelerators to terminal
	epatch "${FILESDIR}/${P}-copy-paste.patch"

	# Improved handling of scrolling for replace-all command
	epatch "${FILESDIR}/${P}-replace-all.patch"

	# Fix background color of the commander entry
	epatch "${FILESDIR}/${P}-background-color.patch"

	# Make multi edit keybinding toggle multi edit mode
	epatch "${FILESDIR}/${P}-keybinding-toggle.patch"

	# Make multi edit menu item proper toggle item
	epatch "${FILESDIR}/${P}-edit-menu.patch"

	# Added commander toggle menu item
	epatch "${FILESDIR}/${P}-commander-menu.patch"

	# disable pyc compiling
	mv py-compile py-compile.orig
	ln -s $(type -P true) py-compile
}

src_test() {
	emake check || die "make check failed"
}

src_install() {
	gnome2_src_install
	# gedit doesn't rely on *.la files
	find "${D}" -name "*.la" -delete || die "*.la files removal failed"
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_need_rebuild
	python_mod_optimize /usr/$(get_libdir)/gedit-2/plugins
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup /usr/$(get_libdir)/gedit-2/plugins
}