app-doc/csound-manual/csound-manual-5.17.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-doc/csound-manual/csound-manual-5.17.ebuild,v 1.1 2012/04/11 22:16:12 radhermit Exp $

EAPI="4"

MY_P="Csound${PV}"

DESCRIPTION="The Csound reference manual"
HOMEPAGE="http://csounds.com/"
SRC_URI="
	mirror://sourceforge/${PN}/${MY_P}_manual_pdf.zip
	linguas_fr? ( mirror://sourceforge/${PN}/${MY_P}_manual-fr_pdf.zip )

	html? (
		mirror://sourceforge/${PN}/${MY_P}_manual_html.zip
		linguas_fr? ( mirror://sourceforge/${PN}/${MY_P}_manual-fr_html.zip )
	)"

LICENSE="FDL-1.3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="html"

LANGS=" fr"
IUSE+="${LANGS// / linguas_}"

DEPEND="app-arch/unzip"

S="${WORKDIR}"

src_unpack() {
	unpack ${MY_P}_manual_pdf.zip

	if use html ; then
		unpack ${MY_P}_manual_html.zip
		mv html html-en
	fi

	local lang
	for lang in ${LANGS} ; do
		use linguas_${lang} || continue
		unpack ${MY_P}_manual-${lang}_pdf.zip
		if use html ; then
			unpack ${MY_P}_manual-${lang}_html.zip
			mv html html-${lang}
		fi
	done
}

src_install() {
	dodoc *.pdf

	if use html ; then
		dohtml -r html-en/*

		local lang
		for lang in ${LANGS} ; do
			use linguas_${lang} || continue
			docinto html-${lang}
			dohtml -r html-${lang}/*
		done
	fi
}