1 files changed, 48 insertions, 0 deletions
diff --git a/net-misc/knock/knock-0.6.ebuild b/net-misc/knock/knock-0.6.ebuild
new file mode 100644
index 000000000000..2e144206dd3e
--- /dev/null
+++ b/net-misc/knock/knock-0.6.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/knock/knock-0.6.ebuild,v 1.1 2013/04/21 07:17:12 xmw Exp $
+
+EAPI=4
+
+DESCRIPTION="A simple port-knocking daemon"
+HOMEPAGE="http://www.zeroflux.org/projects/knock"
+SRC_URI="http://www.zeroflux.org/proj/knock/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="+server"
+
+DEPEND="server? ( net-libs/libpcap )"
+RDEPEND="${DEPEND}
+	server? ( sys-apps/openrc )"
+
+src_prepare() {
+	sed -e "/^AM_CFLAGS/s: -g : :" \
+		-e "/dist_doc_DATA/s:COPYING::" \
+		-i Makefile.in || die
+	sed -e "s:/usr/sbin/iptables:/sbin/iptables:g" \
+		-i knockd.conf || die
+}
+
+src_configure() {
+	econf $(use_enable server knockd)
+}
+
+src_install() {
+	emake DESTDIR="${D}" docdir="${EROOT}/usr/share/doc/${PF}" install
+
+	if use server ; then
+		newinitd "${FILESDIR}"/knockd.initd.2 knock
+		newconfd "${FILESDIR}"/knockd.confd.2 knock
+	fi
+}
+
+pkg_postinst() {
+	if use server && ! has_version net-firewall/iptables ; then
+		einfo
+		elog "You're really encouraged to install net-firewall/iptables to"
+		elog "actually modify your firewall and use the example configuration."
+		einfo
+	fi
+}