1 files changed, 83 insertions, 0 deletions
diff --git a/app-i18n/scim-bridge/scim-bridge-0.4.14.ebuild b/app-i18n/scim-bridge/scim-bridge-0.4.14.ebuild
new file mode 100644
index 000000000000..6ab1fe457c25
--- /dev/null
+++ b/app-i18n/scim-bridge/scim-bridge-0.4.14.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/scim-bridge/scim-bridge-0.4.14.ebuild,v 1.1 2008/01/27 16:35:05 matsuu Exp $
+
+WANT_AUTOMAKE=latest
+WANT_AUTOCONF=latest
+
+inherit autotools eutils qt3 qt4
+
+DESCRIPTION="Yet another IM-client of SCIM"
+HOMEPAGE="http://www.scim-im.org/projects/scim_bridge"
+SRC_URI="mirror://sourceforge/scim/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc64 ~sparc ~x86"
+IUSE="doc gtk qt3 qt4"
+
+RDEPEND=">=app-i18n/scim-1.4.6
+	gtk? (
+		>=x11-libs/gtk+-2.2
+		>=x11-libs/pango-1.1
+	)
+	qt3? (
+		$(qt_min_version 3.3.4)
+		>=x11-libs/pango-1.1
+	)
+	qt4? (
+		$(qt4_min_version 4.0.0)
+		>=x11-libs/pango-1.1
+	)"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+get_gtk_confdir() {
+	if use amd64 || ( [ "${CONF_LIBDIR}" == "lib32" ] && use x86 ) ; then
+		echo "/etc/gtk-2.0/${CHOST}"
+	else
+		echo "/etc/gtk-2.0"
+	fi
+}
+
+pkg_setup() {
+	if use qt3 && ! built_with_use =x11-libs/qt-3* immqt-bc && ! built_with_use =x11-libs/qt-3* immqt; then
+		die "You need to rebuild >=x11-libs/qt-3.3.4 with immqt-bc(recommended) or immqt USE flag enabled."
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/${P}-qt4.patch
+	eautoreconf
+}
+
+src_compile() {
+	econf \
+		$(use_enable gtk gtk2-immodule) \
+		$(use_enable qt3 qt3-immodule) \
+		$(use_enable qt4 qt4-immodule) \
+		$(use_enable doc documents) || die
+	emake || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+
+	dodoc AUTHORS ChangeLog NEWS README
+}
+
+pkg_postinst() {
+	elog
+	elog "If you would like to use ${PN} as default instead of scim, set"
+	elog " $ export GTK_IM_MODULE=scim-bridge"
+	elog " $ export QT_IM_MODULE=scim-bridge"
+	elog
+	[ -x /usr/bin/gtk-query-immodules-2.0 ] && gtk-query-immodules-2.0 > "${ROOT}$(get_gtk_confdir)/gtk.immodules"
+}
+
+pkg_postrm() {
+	[ -x /usr/bin/gtk-query-immodules-2.0 ] && gtk-query-immodules-2.0 > "${ROOT}$(get_gtk_confdir)/gtk.immodules"
+}