1 files changed, 65 insertions, 0 deletions
diff --git a/app-emacs/auctex/auctex-11.88.ebuild b/app-emacs/auctex/auctex-11.88.ebuild
new file mode 100644
index 000000000000..5fa5b3eb2f2e
--- /dev/null
+++ b/app-emacs/auctex/auctex-11.88.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/auctex/auctex-11.88.ebuild,v 1.1 2014/11/01 16:45:58 ulm Exp $
+
+EAPI=5
+
+inherit elisp latex-package
+
+DESCRIPTION="Extended support for writing, formatting and using (La)TeX, Texinfo and BibTeX files"
+HOMEPAGE="http://www.gnu.org/software/auctex/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+ FDL-1.3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris"
+IUSE="preview-latex"
+
+DEPEND="virtual/latex-base
+	preview-latex? (
+		app-text/dvipng
+		app-text/ghostscript-gpl
+	)"
+RDEPEND="${DEPEND}"
+
+TEXMF="/usr/share/texmf-site"
+
+src_prepare() {
+	elisp_src_prepare
+}
+
+src_configure() {
+	EMACS_NAME=emacs EMACS_FLAVOR=emacs econf --disable-build-dir-test \
+		--with-auto-dir="${EPREFIX}/var/lib/auctex" \
+		--with-lispdir="${EPREFIX}${SITELISP}/${PN}" \
+		--with-packagelispdir="${EPREFIX}${SITELISP}/${PN}" \
+		--with-packagedatadir="${EPREFIX}${SITEETC}/${PN}" \
+		--with-texmf-dir="${EPREFIX}${TEXMF}" \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		$(use_enable preview-latex preview)
+}
+
+src_compile() {
+	export VARTEXFONTS="${T}"/fonts
+	emake
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+	elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
+	if use preview-latex; then
+		elisp-site-file-install "${FILESDIR}/60${PN}-gentoo.el"
+	fi
+	dodoc ChangeLog CHANGES FAQ INSTALL PROBLEMS.preview README RELEASE TODO
+}
+
+pkg_postinst() {
+	# rebuild TeX-inputfiles-database
+	use preview-latex && latex-package_pkg_postinst
+	elisp-site-regen
+}
+
+pkg_postrm(){
+	use preview-latex && latex-package_pkg_postrm
+	elisp-site-regen
+}