Version bump

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 09BF4F54C2BA7F3C!)

2 files changed, 124 insertions, 1 deletions

diff --git a/x11-misc/lightdm/ChangeLog b/x11-misc/lightdm/ChangeLog
index f8860044d70c..9b2c19180c82 100644
--- a/x11-misc/lightdm/ChangeLog
+++ b/x11-misc/lightdm/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/lightdm
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.89 2014/04/20 10:19:10 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.90 2014/05/10 10:14:51 hwoarang Exp $
+
+*lightdm-1.10.1 (10 May 2014)
+
+  10 May 2014; Markos Chandras <hwoarang@gentoo.org> +lightdm-1.10.1.ebuild:
+  Version bump
 
 *lightdm-1.4.0-r2 (20 Apr 2014)
 
diff --git a/x11-misc/lightdm/lightdm-1.10.1.ebuild b/x11-misc/lightdm/lightdm-1.10.1.ebuild
new file mode 100644
index 000000000000..dceca4463c07
--- /dev/null
+++ b/x11-misc/lightdm/lightdm-1.10.1.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-1.10.1.ebuild,v 1.1 2014/05/10 10:14:51 hwoarang Exp $
+
+EAPI=5
+inherit autotools eutils pam readme.gentoo systemd
+
+TRUNK_VERSION="1.10"
+DESCRIPTION="A lightweight display manager"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/LightDM"
+SRC_URI="http://launchpad.net/${PN}/${TRUNK_VERSION}/${PV}/+download/${P}.tar.xz
+	mirror://gentoo/introspection-20110205.m4.tar.bz2"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="+gtk +introspection kde qt4 razor"
+REQUIRED_USE="|| ( gtk kde razor )"
+
+COMMON_DEPEND=">=dev-libs/glib-2.32.3:2
+	dev-libs/libxml2
+	sys-apps/accountsservice
+	virtual/pam
+	x11-libs/libX11
+	>=x11-libs/libxklavier-5
+	introspection? ( >=dev-libs/gobject-introspection-1 )
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+		)"
+RDEPEND="${COMMON_DEPEND}
+	>=sys-auth/pambase-20101024-r2"
+DEPEND="${COMMON_DEPEND}
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	gnome-base/gnome-common
+	sys-devel/gettext
+	virtual/pkgconfig"
+PDEPEND="gtk? ( x11-misc/lightdm-gtk-greeter )
+	kde? ( x11-misc/lightdm-kde )
+	razor? ( razorqt-base/razorqt-lightdm-greeter )"
+
+DOCS=( NEWS )
+RESTRICT="test"
+
+src_prepare() {
+	sed -i -e 's:getgroups:lightdm_&:' tests/src/libsystem.c || die #412369
+	sed -i -e '/minimum-uid/s:500:1000:' data/users.conf || die
+
+	einfo "Fixing the session-wrapper variable in lightdm.conf"
+	sed -i -e \
+		"/session-wrapper/s@^.*@session-wrapper=/etc/${PN}/Xsession@" \
+		data/lightdm.conf || die "Failed to fix lightdm.conf"
+
+	epatch_user
+
+	# Remove bogus Makefile statement. This needs to go upstream
+	sed -i /"@YELP_HELP_RULES@"/d help/Makefile.am || die
+	if has_version dev-libs/gobject-introspection; then
+		eautoreconf
+	else
+		AT_M4DIR=${WORKDIR} eautoreconf
+	fi
+}
+
+src_configure() {
+	# Set default values if global vars unset
+	local _greeter _session _user
+	_greeter=${LIGHTDM_GREETER:=lightdm-gtk-greeter}
+	_session=${LIGHTDM_SESSION:=gnome}
+	_user=${LIGHTDM_USER:=root}
+	# Let user know how lightdm is configured
+	einfo "Gentoo configuration"
+	einfo "Default greeter: ${_greeter}"
+	einfo "Default session: ${_session}"
+	einfo "Greeter user: ${_user}"
+
+	# also disable tests because libsystem.c does not build. Tests are
+	# restricted so it does not matter anyway.
+	econf \
+		--localstatedir=/var \
+		--disable-static \
+		--disable-tests \
+		$(use_enable introspection) \
+		$(use_enable qt4 liblightdm-qt) \
+		--disable-liblightdm-qt5 \
+		--with-user-session=${_session} \
+		--with-greeter-session=${_greeter} \
+		--with-greeter-user=${_user} \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	default
+
+	# Delete apparmor profiles because they only work with Ubuntu's
+	# apparmor package. Bug #494426
+	if [[ -d ${D}/etc/apparmor.d ]]; then
+		rm -r "${D}/etc/apparmor.d" || die \
+			"Failed to remove apparmor profiles"
+	fi
+
+	insinto /etc/${PN}
+	doins data/{${PN},keys}.conf
+	doins "${FILESDIR}"/Xsession
+	fperms +x /etc/${PN}/Xsession
+
+	prune_libtool_files --all
+	rm -rf "${ED}"/etc/init
+
+	pamd_mimic system-local-login ${PN} auth account session #372229
+	dopamd "${FILESDIR}"/${PN}-autologin #390863, #423163
+
+	readme.gentoo_create_doc
+
+	systemd_dounit "${FILESDIR}/${PN}.service"
+}