Add XFT (x11-libs/libXft) support.

(Portage version: 2.2.0_alpha85/cvs/Linux x86_64)

1 files changed, 45 insertions, 0 deletions

diff --git a/x11-misc/dmenu/dmenu-4.5-r1.ebuild b/x11-misc/dmenu/dmenu-4.5-r1.ebuild
new file mode 100644
index 000000000000..f9379eb7dc7c
--- /dev/null
+++ b/x11-misc/dmenu/dmenu-4.5-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/dmenu/dmenu-4.5-r1.ebuild,v 1.1 2012/02/08 01:08:36 jer Exp $
+
+EAPI="4"
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="a generic, highly customizable, and efficient menu for the X Window System"
+HOMEPAGE="http://www.suckless.org/programs/dmenu.html"
+SRC_URI="http://dl.suckless.org/tools/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="xft xinerama"
+
+DEPEND="
+	x11-libs/libX11
+	xft? ( x11-libs/libXft )
+	xinerama? ( x11-libs/libXinerama )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	sed -i \
+		-e "s/CFLAGS   = -ansi -pedantic -Wall -Os/CFLAGS  += -ansi -pedantic -Wall/" \
+		-e "s/LDFLAGS  = -s/LDFLAGS  +=/" \
+		-e "s/XINERAMALIBS  =/XINERAMALIBS  ?=/" \
+		-e "s/XINERAMAFLAGS =/XINERAMAFLAGS ?=/" \
+		config.mk || die
+	use xft && epatch "${FILESDIR}"/${PN}-4.5-xft.patch
+}
+
+src_compile() {
+	if use xinerama; then
+		emake CC=$(tc-getCC)
+	else
+		emake CC=$(tc-getCC) XINERAMAFLAGS="" XINERAMALIBS=""
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" install
+}