Bump to 0.7.3

(Portage version: 2.1.9.46/cvs/Linux x86_64)

2 files changed, 72 insertions, 1 deletions

diff --git a/x11-libs/libnotify/ChangeLog b/x11-libs/libnotify/ChangeLog
index ad6d6f19f7ec..d626d9109f77 100644
--- a/x11-libs/libnotify/ChangeLog
+++ b/x11-libs/libnotify/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/libnotify
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/ChangeLog,v 1.69 2011/05/01 17:56:44 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/ChangeLog,v 1.70 2011/05/21 18:45:16 nirbheek Exp $
+
+*libnotify-0.7.3 (21 May 2011)
+
+  21 May 2011; Nirbheek Chauhan <nirbheek@gentoo.org> +libnotify-0.7.3.ebuild:
+  Bump to 0.7.3
 
   01 May 2011; Samuli Suominen <ssuominen@gentoo.org> libnotify-0.7.2.ebuild:
   Use virtual/notification-daemon.
diff --git a/x11-libs/libnotify/libnotify-0.7.3.ebuild b/x11-libs/libnotify/libnotify-0.7.3.ebuild
new file mode 100644
index 000000000000..9f8a35684d22
--- /dev/null
+++ b/x11-libs/libnotify/libnotify-0.7.3.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/libnotify-0.7.3.ebuild,v 1.1 2011/05/21 18:45:16 nirbheek Exp $
+
+EAPI=3
+inherit autotools eutils gnome.org
+
+DESCRIPTION="Notifications library"
+HOMEPAGE="http://www.galago-project.org/"
+SRC_URI="${SRC_URI}
+	mirror://gentoo/introspection-20110205.m4.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="doc +introspection test"
+
+RDEPEND=">=dev-libs/glib-2.26:2
+	x11-libs/gdk-pixbuf:2
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	dev-util/gtk-doc-am
+	doc? ( >=dev-util/gtk-doc-1.14 )
+	test? ( >=x11-libs/gtk+-2.90:3 )"
+PDEPEND="virtual/notification-daemon"
+
+src_unpack() {
+	# If gobject-introspection is installed, we don't need the extra .m4
+	if has_version "dev-libs/gobject-introspection"; then
+		unpack ${P}.tar.bz2
+	else
+		unpack ${A}
+	fi
+}
+
+src_prepare() {
+	# Add configure switch for gtk+:3 based tests
+	# and make tests build only when needed
+	epatch "${FILESDIR}"/${PN}-0.7.1-gtk3-tests.patch
+
+	AT_M4DIR=${WORKDIR} eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--disable-dependency-tracking \
+		$(use_enable introspection) \
+		$(use_enable test tests)
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	dodoc AUTHORS ChangeLog NEWS || die
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}
+
+pkg_preinst() {
+	preserve_old_lib /usr/$(get_libdir)/libnotify.so.1
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /usr/$(get_libdir)/libnotify.so.1
+}