Version bump, drop exynos and freedreno support as they are broken in this release.

(Portage version: 2.1.11.55/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 62 insertions, 1 deletions

diff --git a/x11-libs/libdrm/ChangeLog b/x11-libs/libdrm/ChangeLog
index e3435225643c..3180d465ddf1 100644
--- a/x11-libs/libdrm/ChangeLog
+++ b/x11-libs/libdrm/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for x11-libs/libdrm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.218 2013/02/27 05:40:26 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.219 2013/03/27 10:40:54 chithanh Exp $
+
+*libdrm-2.4.43 (27 Mar 2013)
+
+  27 Mar 2013; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+  +libdrm-2.4.43.ebuild:
+  Version bump, drop exynos and freedreno support as they are broken in this
+  release.
 
   27 Feb 2013; Zac Medico <zmedico@gentoo.org> libdrm-2.4.42.ebuild:
   Add ~arm-linux keyword.
diff --git a/x11-libs/libdrm/libdrm-2.4.43.ebuild b/x11-libs/libdrm/libdrm-2.4.43.ebuild
new file mode 100644
index 000000000000..9fd32a26650b
--- /dev/null
+++ b/x11-libs/libdrm/libdrm-2.4.43.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/libdrm-2.4.43.ebuild,v 1.1 2013/03/27 10:40:54 chithanh Exp $
+
+EAPI=5
+inherit xorg-2
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"
+
+DESCRIPTION="X.Org libdrm library"
+HOMEPAGE="http://dri.freedesktop.org/"
+if [[ ${PV} = 9999* ]]; then
+	SRC_URI=""
+else
+	SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
+fi
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+VIDEO_CARDS="intel nouveau omap radeon vmware"
+for card in ${VIDEO_CARDS}; do
+	IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+
+IUSE="${IUSE_VIDEO_CARDS} libkms"
+RESTRICT="test" # see bug #236845
+
+RDEPEND="dev-libs/libpthread-stubs
+	video_cards_intel? ( >=x11-libs/libpciaccess-0.10 )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.4.28-solaris.patch
+)
+
+src_prepare() {
+	if [[ ${PV} = 9999* ]]; then
+		# tests are restricted, no point in building them
+		sed -ie 's/tests //' "${S}"/Makefile.am
+	fi
+	xorg-2_src_prepare
+}
+
+src_configure() {
+	XORG_CONFIGURE_OPTIONS=(
+		--enable-udev
+		$(use_enable video_cards_intel intel)
+		$(use_enable video_cards_nouveau nouveau)
+		$(use_enable video_cards_omap omap-experimental-api)
+		$(use_enable video_cards_radeon radeon)
+		$(use_enable video_cards_vmware vmwgfx)
+		$(use_enable libkms)
+	)
+	xorg-2_src_configure
+}