Version bump (bug #256065). Clean out version 1.5012.

(Portage version: 2.1.6.7/cvs/Linux x86_64)

1 files changed, 53 insertions, 0 deletions

diff --git a/sys-fs/ntfs3g/ntfs3g-2009.2.1.ebuild b/sys-fs/ntfs3g/ntfs3g-2009.2.1.ebuild
new file mode 100644
index 000000000000..9d53512d8b8a
--- /dev/null
+++ b/sys-fs/ntfs3g/ntfs3g-2009.2.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/ntfs3g/ntfs3g-2009.2.1.ebuild,v 1.1 2009/02/12 16:21:24 chutzpah Exp $
+
+MY_PN="${PN/3g/-3g}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Open source read-write NTFS driver that runs under FUSE"
+HOMEPAGE="http://www.ntfs-3g.org"
+SRC_URI="http://www.ntfs-3g.org/${MY_P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug hal suid"
+
+RDEPEND="hal? ( sys-apps/hal )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_compile() {
+	econf \
+		--docdir="/usr/share/doc/${PF}" \
+		--enable-ldscript \
+		--disable-ldconfig \
+		$(use_enable debug)
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "install failed"
+
+	prepalldocs
+	dodoc AUTHORS ChangeLog CREDITS
+
+	use suid && fperms u+s "/bin/${MY_PN}"
+
+	if use hal; then
+		insinto /etc/hal/fdi/policy/
+		newins "${FILESDIR}/10-ntfs3g.fdi.2009" "10-ntfs3g.fdi"
+	fi
+}
+
+pkg_postinst() {
+	if use suid; then
+		ewarn
+		ewarn "You have chosen to install ${PN} with the binary setuid root. This"
+		ewarn "means that if there any undetected vulnerabilities in the binary,"
+		ewarn "then local users may be able to gain root access on your machine."
+		ewarn
+	fi
+}