Fix uninitialized memory usage #349339 by David Flogeras. Convert to EAPI=2 for fun.

(Portage version: 2.2.0_alpha10/cvs/Linux x86_64)

1 files changed, 44 insertions, 0 deletions

diff --git a/sys-devel/bc/bc-1.06.95-r1.ebuild b/sys-devel/bc/bc-1.06.95-r1.ebuild
new file mode 100644
index 000000000000..1029ed5a98d0
--- /dev/null
+++ b/sys-devel/bc/bc-1.06.95-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/bc/bc-1.06.95-r1.ebuild,v 1.1 2010/12/26 18:49:14 vapier Exp $
+
+EAPI="2"
+
+inherit eutils flag-o-matic
+
+DESCRIPTION="Handy console-based calculator utility"
+HOMEPAGE="http://www.gnu.org/software/bc/bc.html"
+SRC_URI="ftp://alpha.gnu.org/gnu/bc/${P}.tar.bz2
+	mirror://gnu/bc/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="libedit readline static"
+
+RDEPEND="readline? ( >=sys-libs/readline-4.1 >=sys-libs/ncurses-5.2 )
+	libedit? ( dev-libs/libedit )"
+DEPEND="${RDEPEND}
+	sys-devel/flex"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-void_uninitialized.patch #349339
+}
+
+src_configure() {
+	local myconf
+	if use readline ; then
+		myconf="--with-readline --without-libedit"
+	elif use libedit ; then
+		myconf="--without-readline --with-libedit"
+	else
+		myconf="--without-readline --without-libedit"
+	fi
+	use static && append-ldflags -static
+	econf ${myconf}
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	dodoc AUTHORS FAQ NEWS README ChangeLog
+}