Version bump #554968 by Manuel Rüger. Add support for USE=static #484538 by Austin S. Hemmelgarn.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

2 files changed, 62 insertions, 1 deletions

diff --git a/sys-block/thin-provisioning-tools/ChangeLog b/sys-block/thin-provisioning-tools/ChangeLog
index 385d19060d77..639bbecc8833 100644
--- a/sys-block/thin-provisioning-tools/ChangeLog
+++ b/sys-block/thin-provisioning-tools/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for sys-block/thin-provisioning-tools
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-block/thin-provisioning-tools/ChangeLog,v 1.64 2015/07/29 05:29:36 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-block/thin-provisioning-tools/ChangeLog,v 1.65 2015/07/29 05:44:08 vapier Exp $
+
+*thin-provisioning-tools-0.5.3 (29 Jul 2015)
+
+  29 Jul 2015; Mike Frysinger <vapier@gentoo.org>
+  +thin-provisioning-tools-0.5.3.ebuild:
+  Version bump #554968 by Manuel Rüger.  Add support for USE=static #484538 by
+  Austin S. Hemmelgarn.
 
   29 Jul 2015; Mike Frysinger <vapier@gentoo.org>
   thin-provisioning-tools-0.4.1.ebuild:
diff --git a/sys-block/thin-provisioning-tools/thin-provisioning-tools-0.5.3.ebuild b/sys-block/thin-provisioning-tools/thin-provisioning-tools-0.5.3.ebuild
new file mode 100644
index 000000000000..dcc6114b0484
--- /dev/null
+++ b/sys-block/thin-provisioning-tools/thin-provisioning-tools-0.5.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-block/thin-provisioning-tools/thin-provisioning-tools-0.5.3.ebuild,v 1.1 2015/07/29 05:44:08 vapier Exp $
+
+EAPI="5"
+
+inherit autotools eutils flag-o-matic
+
+DESCRIPTION="A suite of tools for thin provisioning on Linux"
+HOMEPAGE="http://github.com/jthornber/thin-provisioning-tools"
+SRC_URI="http://github.com/jthornber/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="static test"
+
+LIB_DEPEND="dev-libs/expat[static-libs(+)]
+	dev-libs/libaio[static-libs(+)]"
+RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )"
+# || ( ) is a non-future proof workaround for Portage unefficiency wrt #477050
+DEPEND="${RDEPEND}
+	static? ( ${LIB_DEPEND} )
+	test? (
+		|| ( dev-lang/ruby:2.9 dev-lang/ruby:2.8 dev-lang/ruby:2.7 dev-lang/ruby:2.6 dev-lang/ruby:2.5 dev-lang/ruby:2.4 dev-lang/ruby:2.3 dev-lang/ruby:2.2 dev-lang/ruby:2.1 dev-lang/ruby:2.0 dev-lang/ruby:1.9 )
+		dev-cpp/gmock
+		dev-util/cucumber
+		dev-util/aruba
+	)
+	dev-libs/boost"
+
+src_prepare() {
+	sed -i -e '/^INSTALL_PROGRAM/s:-s::' Makefile.in || die
+	epatch_user
+	eautoreconf
+}
+
+src_configure() {
+	use static && append-ldflags -static
+	econf \
+		--prefix="${EPREFIX}"/ \
+		--bindir="${EPREFIX}"/sbin \
+		--with-optimisation='' \
+		$(use_enable test testing)
+}
+
+src_test() {
+	emake unit-test
+}
+
+src_install() {
+	emake DESTDIR="${D}" DATADIR="${ED}/usr/share" install
+	dodoc README.md TODO.org
+}