Add a new revision using EAPI=2.

(Portage version: 2.2_rc11/cvs/Linux 2.6.26-gentoo-r1 x86_64)

2 files changed, 80 insertions, 1 deletions

diff --git a/sys-auth/pambase/ChangeLog b/sys-auth/pambase/ChangeLog
index 448944cb4bc3..3dd56a7f9442 100644
--- a/sys-auth/pambase/ChangeLog
+++ b/sys-auth/pambase/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-auth/pambase
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/pambase/ChangeLog,v 1.54 2008/08/22 20:53:25 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/pambase/ChangeLog,v 1.55 2008/09/29 05:25:07 flameeyes Exp $
+
+*pambase-20080801-r1 (29 Sep 2008)
+
+  29 Sep 2008; Diego Pettenò <flameeyes@gentoo.org>
+  +pambase-20080801-r1.ebuild:
+  Add a new revision using EAPI=2.
 
   22 Aug 2008; Alexis Ballier <aballier@gentoo.org> pambase-20080801.ebuild:
   keyword ~sparc-fbsd
diff --git a/sys-auth/pambase/pambase-20080801-r1.ebuild b/sys-auth/pambase/pambase-20080801-r1.ebuild
new file mode 100644
index 000000000000..45f87a38b89d
--- /dev/null
+++ b/sys-auth/pambase/pambase-20080801-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/pambase/pambase-20080801-r1.ebuild,v 1.1 2008/09/29 05:25:07 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils
+
+DESCRIPTION="PAM base configuration files"
+HOMEPAGE="http://www.gentoo.org/proj/en/base/pam/"
+SRC_URI="http://www.flameeyes.eu/gentoo-distfiles/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="debug cracklib passwdqc consolekit gnome-keyring selinux mktemp ssh +sha512"
+RESTRICT="binchecks"
+
+RDEPEND="
+	|| (
+		>=sys-libs/pam-0.99.9.0-r1
+		( sys-auth/openpam
+		  || ( sys-freebsd/freebsd-pam-modules sys-netbsd/netbsd-pam-modules )
+		)
+	)
+	cracklib? ( >=sys-libs/pam-0.99[cracklib] )
+	consolekit? ( sys-auth/consolekit[pam] )
+	gnome-keyring? ( >=gnome-base/gnome-keyring-2.20[pam] )
+	selinux? ( >=sys-libs/pam-0.99[selinux] )
+	passwdqc? ( >=sys-auth/pam_passwdqc-1.0.4 )
+	mktemp? ( sys-auth/pam_mktemp )
+	ssh? ( sys-auth/pam_ssh )
+	sha512? ( >=sys-libs/pam-1.0.1 )
+	!<sys-freebsd/freebsd-pam-modules-6.2-r1
+	!<sys-libs/pam-0.99.9.0-r1"
+DEPEND=""
+
+src_compile() {
+	has_version sys-libs/pam && implementation="linux-pam"
+	has_version sys-auth/openpam && implementation="openpam"
+
+	emake \
+		GIT=true \
+		DEBUG=$(use debug && echo yes || echo no) \
+		CRACKLIB=$(use cracklib && echo yes || echo no) \
+		PASSWDQC=$(use passwdqc && echo yes || echo no) \
+		CONSOLEKIT=$(use consolekit && echo yes || echo no) \
+		GNOME_KEYRING=$(use gnome-keyring && echo yes || echo no) \
+		SELINUX=$(use selinux && echo yes || echo no) \
+		MKTEMP=$(use mktemp && echo yes || echo no) \
+		PAM_SSH=$(use ssh && echo yes || echo no) \
+		SHA512=$(use sha512 && echo yes || echo no) \
+		IMPLEMENTATION=${implementation} \
+		|| die "emake failed"
+}
+
+src_install() {
+	emake GIT=true DESTDIR="${D}" install || die "emake install failed"
+}
+
+pkg_postinst() {
+	if use sha512; then
+		elog "Starting from version 20080801, pambase optionally enables"
+		elog "SHA512-hashed passwords. For this to work, you need sys-libs/pam-1.0.1"
+		elog "built against sys-libs/glibc-2.7 or later."
+		elog "If you don't have support for this, it will automatically fallback"
+		elog "to MD5-hashed passwords, just like before."
+		elog
+		elog "Please note that the change only affects the newly-changed passwords"
+		elog "and that SHA512-hashed passwords will not work on earlier versions"
+		elog "of glibc or Linux-PAM."
+	fi
+}