version bump and sync live ebuild. We dropped the --libdir= configure switch to install the pkg-config file in the proper location.

(Portage version: 2.2.0_alpha144/cvs/Linux i686, signed Manifest commit with key 0x30C46538)

3 files changed, 99 insertions, 3 deletions

diff --git a/sys-apps/kmod/ChangeLog b/sys-apps/kmod/ChangeLog
index 324eeb3e4f32..3c1436c0a07e 100644
--- a/sys-apps/kmod/ChangeLog
+++ b/sys-apps/kmod/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for sys-apps/kmod
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.61 2012/12/04 04:16:52 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.62 2012/12/05 17:13:29 williamh Exp $
+
+*kmod-12 (05 Dec 2012)
+
+  05 Dec 2012; William Hubbs <williamh@gentoo.org> +kmod-12.ebuild,
+  kmod-9999.ebuild:
+  version bump and sync live ebuild. We dropped the --libdir= configure switch
+  to install the pkg-config file in the proper location.
 
 *kmod-11-r4 (04 Dec 2012)
 
diff --git a/sys-apps/kmod/kmod-12.ebuild b/sys-apps/kmod/kmod-12.ebuild
new file mode 100644
index 000000000000..4607f9b37894
--- /dev/null
+++ b/sys-apps/kmod/kmod-12.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-12.ebuild,v 1.1 2012/12/05 17:13:29 williamh Exp $
+
+EAPI=4
+
+inherit autotools eutils libtool multilib
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
+	inherit git-2
+else
+	SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="library and tools for managing linux kernel modules"
+HOMEPAGE="http://git.kernel.org/?p=utils/kernel/kmod/kmod.git"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="debug doc lzma static-libs +tools zlib"
+
+# Upstream does not support running the test suite with custom configure flags.
+# I was also told that the test suite is intended for kmod developers.
+# So we have to restrict it.
+# See bug #408915.
+RESTRICT="test"
+
+RDEPEND="!sys-apps/module-init-tools
+	!sys-apps/modutils
+	lzma? ( >=app-arch/xz-utils-5.0.4-r1 )
+	zlib? ( >=sys-libs/zlib-1.2.6 )" #427130
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	doc? ( dev-util/gtk-doc )
+	lzma? ( virtual/pkgconfig )
+	zlib? ( virtual/pkgconfig )"
+
+src_prepare()
+{
+	if [ ! -e configure ]; then
+		if use doc; then
+			gtkdocize --copy --docdir libkmod/docs || die
+		else
+			touch libkmod/docs/gtk-doc.make
+		fi
+		eautoreconf
+	else
+		elibtoolize
+	fi
+}
+
+src_configure()
+{
+	econf \
+		--bindir=/bin \
+		--with-rootlibdir=/$(get_libdir) \
+		$(use_enable static-libs static) \
+		$(use_enable tools) \
+		$(use_enable debug) \
+		$(use_enable doc gtk-doc) \
+		$(use_with lzma xz) \
+		$(use_with zlib)
+}
+
+src_install()
+{
+	default
+	prune_libtool_files
+
+	if use tools; then
+		local cmd
+		for cmd in depmod insmod lsmod modinfo modprobe rmmod; do
+			dosym kmod /bin/${cmd}
+		done
+		# Compatibility symlink(s):
+		# These are both hardcoded in the Linux kernel source tree wrt #426698
+		dosym /bin/kmod /sbin/depmod
+		dosym /bin/kmod /sbin/modprobe
+	fi
+
+	cat <<-EOF > "${T}"/usb-load-ehci-first.conf
+	softdep uhci_hcd pre: ehci_hcd
+	softdep ohci_hcd pre: ehci_hcd
+	EOF
+
+	insinto /lib/modprobe.d
+	doins "${T}"/usb-load-ehci-first.conf #260139
+}
diff --git a/sys-apps/kmod/kmod-9999.ebuild b/sys-apps/kmod/kmod-9999.ebuild
index 95d16394f88c..51ea396ab4a1 100644
--- a/sys-apps/kmod/kmod-9999.ebuild
+++ b/sys-apps/kmod/kmod-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.41 2012/12/04 04:16:52 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.42 2012/12/05 17:13:29 williamh Exp $
 
 EAPI=4
 
@@ -55,7 +55,6 @@ src_configure()
 {
 	econf \
 		--bindir=/bin \
-		--libdir=/$(get_libdir) \
 		--with-rootlibdir=/$(get_libdir) \
 		$(use_enable static-libs static) \
 		$(use_enable tools) \