Merge ebuild versions and version bump #255095 by Krzysztof Oledzki.

(Portage version: 2.2_rc20/cvs/Linux 2.6.28 x86_64)

3 files changed, 171 insertions, 13 deletions

diff --git a/sys-apps/iproute2/ChangeLog b/sys-apps/iproute2/ChangeLog
index ea83d543d8a0..71894f154097 100644
--- a/sys-apps/iproute2/ChangeLog
+++ b/sys-apps/iproute2/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/iproute2
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.114 2008/11/27 20:48:07 vapier Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.115 2009/01/17 17:11:14 vapier Exp $
+
+*iproute2-2.6.28 (17 Jan 2009)
+
+  17 Jan 2009; Mike Frysinger <vapier@gentoo.org> +iproute2-2.6.28.ebuild,
+  iproute2-9999.ebuild:
+  Merge ebuild versions and version bump #255095 by Krzysztof Oledzki.
 
   27 Nov 2008; Mike Frysinger <vapier@gentoo.org> iproute2-2.6.26-r2.ebuild:
   Add a blocker on iproute2 #248092 by Diego E. Pettenò.
diff --git a/sys-apps/iproute2/iproute2-2.6.28.ebuild b/sys-apps/iproute2/iproute2-2.6.28.ebuild
new file mode 100644
index 000000000000..763166f38512
--- /dev/null
+++ b/sys-apps/iproute2/iproute2-2.6.28.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-2.6.28.ebuild,v 1.1 2009/01/17 17:11:14 vapier Exp $
+
+inherit eutils toolchain-funcs
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/shemminger/iproute2.git"
+	inherit git
+	SRC_URI=""
+	KEYWORDS=""
+else
+	if [[ ${PV} == *.*.*.* ]] ; then
+		MY_PV=${PV%.*}
+	else
+		MY_PV=${PV}
+	fi
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="http://developer.osdl.org/dev/iproute2/download/${MY_P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+	S=${WORKDIR}/${MY_P}
+fi
+
+DESCRIPTION="kernel routing and traffic control utilities"
+HOMEPAGE="http://linux-net.osdl.org/index.php/Iproute2"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="atm berkdb minimal"
+
+RDEPEND="!net-misc/arpd
+	!minimal? ( berkdb? ( sys-libs/db ) )
+	atm? ( net-dialup/linux-atm )"
+DEPEND="${RDEPEND}
+	elibc_glibc? ( >=sys-libs/glibc-2.7 )
+	>=virtual/os-headers-2.6.25"
+
+src_unpack() {
+	if [[ ${PV} == "9999" ]] ; then
+		git_src_unpack
+	else
+		unpack ${A}
+	fi
+	cd "${S}"
+	sed -i "s:-O2:${CFLAGS} ${CPPFLAGS}:" Makefile || die "sed Makefile failed"
+
+	# build against system headers
+	rm -r include/linux include/netinet #include/ip{,6}tables{,_common}.h include/libiptc
+
+	epatch "${FILESDIR}"/${PN}-2.6.26-ldflags.patch #236861
+
+	local check base=${PORTAGE_CONFIGROOT}/etc/portage/patches
+	for check in {${CATEGORY}/${PF},${CATEGORY}/${P},${CATEGORY}/${PN}}; do
+		EPATCH_SOURCE=${base}/${CTARGET}/${check}
+		[[ -r ${EPATCH_SOURCE} ]] || EPATCH_SOURCE=${base}/${CHOST}/${check}
+		[[ -r ${EPATCH_SOURCE} ]] || EPATCH_SOURCE=${base}/${check}
+		if [[ -d ${EPATCH_SOURCE} ]] ; then
+			EPATCH_SUFFIX="patch"
+			EPATCH_FORCE="yes" \
+			EPATCH_MULTI_MSG="Applying user patches from ${EPATCH_SOURCE} ..." \
+			epatch
+			break
+		fi
+	done
+
+	# don't build arpd if USE=-berkdb #81660
+	use berkdb || sed -i '/^TARGETS=/s: arpd : :' misc/Makefile
+	# Multilib fixes
+	sed -i 's:/usr/local:/usr:' tc/m_ipt.c include/iptables.h
+	sed -i "s:/usr/lib:/usr/$(get_libdir):g" \
+		netem/Makefile tc/{Makefile,tc.c,q_netem.c,m_ipt.c} include/iptables.h || die
+	sed -i "s:/lib/tc:$(get_libdir)/tc:g" tc/Makefile || die
+	# Use correct iptables dir, #144265
+	sed -i "s:/usr/local/lib/iptables:/$(get_libdir)/iptables:g" \
+		include/iptables.h
+}
+
+src_compile() {
+	echo -n 'TC_CONFIG_ATM:=' > Config
+	use atm \
+		&& echo 'y' >> Config \
+		|| echo 'n' >> Config
+
+	use minimal && sed -i -e '/^SUBDIRS=/s:=.*:=lib tc:' Makefile
+	emake \
+		CC="$(tc-getCC)" \
+		AR="$(tc-getAR)" \
+		|| die "make"
+}
+
+src_install() {
+	if use minimal ; then
+		into /
+		dosbin tc/tc || die "minimal"
+		return 0
+	fi
+
+	emake \
+		DESTDIR="${D}" \
+		SBINDIR=/sbin \
+		DOCDIR=/usr/share/doc/${PF} \
+		MANDIR=/usr/share/man \
+		install \
+		|| die "make install failed"
+	if use berkdb ; then
+		dodir /var/lib/arpd
+		# bug 47482, arpd doesn't need to be in /sbin
+		dodir /usr/sbin
+		mv "${D}"/sbin/arpd "${D}"/usr/sbin/
+	fi
+}
diff --git a/sys-apps/iproute2/iproute2-9999.ebuild b/sys-apps/iproute2/iproute2-9999.ebuild
index 25611cbb1ef1..c553e208363a 100644
--- a/sys-apps/iproute2/iproute2-9999.ebuild
+++ b/sys-apps/iproute2/iproute2-9999.ebuild
@@ -1,28 +1,67 @@
-# Copyright 1999-2007 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v 1.2 2008/06/09 00:57:06 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v 1.3 2009/01/17 17:11:14 vapier Exp $
 
-EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/shemminger/iproute2.git"
-inherit eutils toolchain-funcs git
+inherit eutils toolchain-funcs
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/shemminger/iproute2.git"
+	inherit git
+	SRC_URI=""
+	KEYWORDS=""
+else
+	if [[ ${PV} == *.*.*.* ]] ; then
+		MY_PV=${PV%.*}
+	else
+		MY_PV=${PV}
+	fi
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="http://developer.osdl.org/dev/iproute2/download/${MY_P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+	S=${WORKDIR}/${MY_P}
+fi
 
 DESCRIPTION="kernel routing and traffic control utilities"
 HOMEPAGE="http://linux-net.osdl.org/index.php/Iproute2"
-SRC_URI=""
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS=""
 IUSE="atm berkdb minimal"
 
-RDEPEND="!minimal? ( berkdb? ( sys-libs/db ) )
+RDEPEND="!net-misc/arpd
+	!minimal? ( berkdb? ( sys-libs/db ) )
 	atm? ( net-dialup/linux-atm )"
 DEPEND="${RDEPEND}
-	>=virtual/os-headers-2.4.21"
+	elibc_glibc? ( >=sys-libs/glibc-2.7 )
+	>=virtual/os-headers-2.6.25"
 
 src_unpack() {
-	git_src_unpack
+	if [[ ${PV} == "9999" ]] ; then
+		git_src_unpack
+	else
+		unpack ${A}
+	fi
 	cd "${S}"
-	sed -i "s:-O2:${CFLAGS}:" Makefile || die "sed Makefile failed"
+	sed -i "s:-O2:${CFLAGS} ${CPPFLAGS}:" Makefile || die "sed Makefile failed"
+
+	# build against system headers
+	rm -r include/linux include/netinet #include/ip{,6}tables{,_common}.h include/libiptc
+
+	epatch "${FILESDIR}"/${PN}-2.6.26-ldflags.patch #236861
+
+	local check base=${PORTAGE_CONFIGROOT}/etc/portage/patches
+	for check in {${CATEGORY}/${PF},${CATEGORY}/${P},${CATEGORY}/${PN}}; do
+		EPATCH_SOURCE=${base}/${CTARGET}/${check}
+		[[ -r ${EPATCH_SOURCE} ]] || EPATCH_SOURCE=${base}/${CHOST}/${check}
+		[[ -r ${EPATCH_SOURCE} ]] || EPATCH_SOURCE=${base}/${check}
+		if [[ -d ${EPATCH_SOURCE} ]] ; then
+			EPATCH_SUFFIX="patch"
+			EPATCH_FORCE="yes" \
+			EPATCH_MULTI_MSG="Applying user patches from ${EPATCH_SOURCE} ..." \
+			epatch
+			break
+		fi
+	done
 
 	# don't build arpd if USE=-berkdb #81660
 	use berkdb || sed -i '/^TARGETS=/s: arpd : :' misc/Makefile
@@ -30,7 +69,8 @@ src_unpack() {
 	sed -i 's:/usr/local:/usr:' tc/m_ipt.c include/iptables.h
 	sed -i "s:/usr/lib:/usr/$(get_libdir):g" \
 		netem/Makefile tc/{Makefile,tc.c,q_netem.c,m_ipt.c} include/iptables.h || die
-	# Use correct iptables dir, #144265.
+	sed -i "s:/lib/tc:$(get_libdir)/tc:g" tc/Makefile || die
+	# Use correct iptables dir, #144265
 	sed -i "s:/usr/local/lib/iptables:/$(get_libdir)/iptables:g" \
 		include/iptables.h
 }
@@ -59,6 +99,7 @@ src_install() {
 		DESTDIR="${D}" \
 		SBINDIR=/sbin \
 		DOCDIR=/usr/share/doc/${PF} \
+		MANDIR=/usr/share/man \
 		install \
 		|| die "make install failed"
 	if use berkdb ; then