Version bump

(Portage version: 2.2.01.21688-prefix/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

3 files changed, 154 insertions, 162 deletions

diff --git a/sci-libs/mathgl/ChangeLog b/sci-libs/mathgl/ChangeLog
index 7997b1f65db2..f3b71faee4c5 100644
--- a/sci-libs/mathgl/ChangeLog
+++ b/sci-libs/mathgl/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-libs/mathgl
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/mathgl/ChangeLog,v 1.33 2013/03/02 23:23:19 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/mathgl/ChangeLog,v 1.34 2013/03/21 15:40:47 bicatali Exp $
+
+*mathgl-2.1.2 (21 Mar 2013)
+
+  21 Mar 2013; Sébastien Fabbro <bicatali@gentoo.org> +mathgl-2.1.2.ebuild,
+  -mathgl-1.11.2.ebuild:
+  Version bump
 
   02 Mar 2013; Markos Chandras <hwoarang@gentoo.org> mathgl-1.11.2.ebuild,
   mathgl-2.0.3.ebuild:
diff --git a/sci-libs/mathgl/mathgl-1.11.2.ebuild b/sci-libs/mathgl/mathgl-1.11.2.ebuild
deleted file mode 100644
index 8d96b07233ba..000000000000
--- a/sci-libs/mathgl/mathgl-1.11.2.ebuild
+++ /dev/null
@@ -1,161 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/mathgl/mathgl-1.11.2.ebuild,v 1.5 2013/03/02 23:23:19 hwoarang Exp $
-
-EAPI=4
-
-WX_GTK_VER=2.8
-
-PYTHON_DEPEND="python? 2"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="3.* 2.7-pypy-* *-jython"
-
-AUTOTOOLS_AUTORECONF=true
-
-inherit autotools-utils eutils python toolchain-funcs versionator wxwidgets
-
-DESCRIPTION="Math Graphics Library"
-HOMEPAGE="http://mathgl.sourceforge.net/"
-SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz mirror://sourceforge/${PN}/STIX_font.tgz"
-
-LICENSE="LGPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc fltk gif glut gsl hdf5 jpeg mpi octave python qt4 wxwidgets static-libs"
-
-RDEPEND="
-	media-libs/libpng
-	sys-libs/zlib
-	virtual/opengl
-	fltk? ( x11-libs/fltk:1 )
-	gif? ( media-libs/giflib )
-	glut? ( media-libs/freeglut )
-	gsl? ( sci-libs/gsl )
-	hdf5? ( >=sci-libs/hdf5-1.8[mpi=] )
-	jpeg? ( virtual/jpeg )
-	octave? ( >=sci-mathematics/octave-3.4.0 )
-	python? ( dev-python/numpy )
-	qt4? ( dev-qt/qtgui:4 )
-	wxwidgets? ( x11-libs/wxGTK:2.8 )"
-DEPEND="${RDEPEND}
-	sys-devel/libtool:2
-	doc? ( app-text/texi2html virtual/texi2dvi )
-	octave? ( dev-lang/swig )
-	python? ( dev-lang/swig )"
-
-REQUIRED_USE="mpi? ( hdf5 ) "
-
-AUTOTOOLS_IN_SOURCE_BUILD=1
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.10.2-gcc43.patch
-	"${FILESDIR}"/${PN}-octave-3.4.patch
-	"${FILESDIR}"/${P}-zlib.patch
-	"${FILESDIR}"/${P}-cast.patch
-	)
-
-pkg_setup() {
-	if ! version_is_at_least "4.3.0" "$(gcc-version)"; then
-		eerror "You need >=gcc-4.3.0 to compile this package"
-		die "Wrong gcc version"
-	fi
-	if use mpi; then
-		export CC=mpicc
-		export CXX=mpicxx
-	fi
-	use python && python_pkg_setup
-	use wxwidgets && wxwidgets_pkg_setup
-}
-
-src_unpack() {
-	unpack ${A}
-	[[ -d "${S}"/fonts ]] || mkdir "${S}"/fonts
-	cd "${S}"/fonts
-	unpack STIX_font.tgz
-}
-
-src_prepare() {
-	# correct location of numpy/arrayobject.h
-	if use python; then
-		sed \
-			-e '/SUBDIRS/s:lang::g' \
-			-i Makefile.am || die
-	fi
-
-	echo "#!${EPREFIX}/bin/sh" > config/py-compile
-
-	autotools-utils_src_prepare
-}
-
-src_configure() {
-	local myeconfargs=(
-		--docdir="${EPREFIX}/usr/share/doc/${PF}"
-		$(use_enable glut)
-		$(use_enable qt4 qt)
-		$(use_enable wxwidgets wx)
-		$(use_enable fltk)
-		$(use_enable gif)
-		$(use_enable jpeg)
-		$(use_enable hdf5 hdf5_18)
-		$(use_enable python)
-		$(use_enable octave)
-		$(use_enable gsl)
-		$(use_enable doc docs)
-		)
-	autotools-utils_src_configure
-}
-
-src_compile() {
-	# see bug #249627
-	local JOBS
-	use doc && MAKEOPTS+=" -j1"
-
-	autotools-utils_src_compile
-
-	if use python; then
-		python_copy_sources lang
-		compilation() {
-			local numpy_h
-			numpy_h=$(python_get_sitedir)/numpy/core/include/numpy/arrayobject.h
-			einfo "fixing numpy.i for Python-${PYTHON_ABI}"
-			sed -e "s|<numpy/arrayobject.h>|\"${numpy_h}\"|" \
-				-i numpy.i \
-				|| die "sed failed"
-			emake PYTHON_HEADERS="-I$(python_get_includedir)" pyexecdir="$(python_get_sitedir)"
-		}
-		python_execute_function -s --source-dir lang compilation
-	fi
-}
-
-src_install() {
-	autotools-utils_src_install
-
-	if use python; then
-		installation() {
-			emake DESTDIR="${D}" PYTHON="$(PYTHON)" pyexecdir="$(python_get_sitedir)" pythondir="$(python_get_sitedir)" install
-		}
-		python_execute_function -s --source-dir lang installation
-		python_clean_installation_image
-	fi
-}
-
-pkg_postinst() {
-	if use octave; then
-		octave <<-EOF
-		pkg install /usr/share/${PN}/octave/${PN}.tar.gz
-		EOF
-	fi
-	use python && python_mod_optimize ${PN}.py
-}
-
-pkg_prerm() {
-	if use octave; then
-		octave <<-EOF
-		pkg uninstall ${PN}
-		EOF
-	fi
-}
-
-pkg_postrm() {
-	use python && python_mod_cleanup ${PN}.py
-}
diff --git a/sci-libs/mathgl/mathgl-2.1.2.ebuild b/sci-libs/mathgl/mathgl-2.1.2.ebuild
new file mode 100644
index 000000000000..4ffccd68b545
--- /dev/null
+++ b/sci-libs/mathgl/mathgl-2.1.2.ebuild
@@ -0,0 +1,147 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/mathgl/mathgl-2.1.2.ebuild,v 1.1 2013/03/21 15:40:47 bicatali Exp $
+
+EAPI=5
+
+WX_GTK_VER=2.8
+
+inherit cmake-utils eutils python wxwidgets multilib flag-o-matic
+
+DESCRIPTION="Math Graphics Library"
+HOMEPAGE="http://mathgl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz mirror://sourceforge/${PN}/STIX_font.tgz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc fltk gif glut gsl hdf hdf5 jpeg mpi octave opengl pdf
+	png python qt4 static-libs threads wxwidgets zlib"
+
+LANGS="ru"
+for l in ${LANGS}; do
+	IUSE+=" linguas_${l}"
+done
+
+RDEPEND="
+	!sci-visualization/udav
+	virtual/opengl
+	fltk? ( x11-libs/fltk:1 )
+	gif? ( media-libs/giflib )
+	glut? ( media-libs/freeglut )
+	gsl? ( sci-libs/gsl )
+	hdf? ( sci-libs/hdf )
+	hdf5? ( >=sci-libs/hdf5-1.8[mpi=] )
+	jpeg? ( virtual/jpeg )
+	octave? ( >=sci-mathematics/octave-3.4.0 )
+	pdf? ( media-libs/libharu )
+	png? ( media-libs/libpng )
+	python? ( dev-python/numpy )
+	qt4? ( dev-qt/qtgui:4 )
+	wxwidgets? ( x11-libs/wxGTK:2.8 )
+	zlib? ( sys-libs/zlib )"
+
+DEPEND="${RDEPEND}
+	doc? ( app-text/texi2html virtual/texi2dvi )
+	octave? ( dev-lang/swig )
+	python? ( dev-lang/swig )"
+
+REQUIRED_USE="mpi? ( hdf5 ) png? ( zlib ) pdf? ( png )"
+
+pkg_setup() {
+	use mpi && export CC=mpicc CXX=mpicxx
+	use python && python_pkg_setup
+	use wxwidgets && wxwidgets_pkg_setup
+}
+
+src_unpack() {
+	unpack ${A}
+	[[ -d "${S}"/fonts ]] || mkdir "${S}"/fonts
+	cd "${S}"/fonts
+	unpack STIX_font.tgz
+}
+
+src_prepare() {
+	# fix for location of hdf headers
+	sed -i -e 's:hdf/::g' src/data_io.cpp || die
+	# bored of reporting bad libdir upstream
+	sed -i \
+		-e '/DESTINATION/s:lib$:lib${LIB_SUFFIX}:g' \
+		{src,widgets}/CMakeLists.txt || die
+	echo "" > lang/install.m || die
+	# fix desktop file
+	sed -i -e 's/.png//' udav/udav.desktop || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DHDF4_INCLUDE_DIR="${EPREFIX}/usr/include"
+		$(cmake-utils_use doc enable-doc)
+		$(cmake-utils_use fltk enable-fltk)
+		$(cmake-utils_use gif enable-gif)
+		$(cmake-utils_use glut enable-glut)
+		$(cmake-utils_use gsl enable-gsl)
+		$(cmake-utils_use hdf enable-hdf4)
+		$(cmake-utils_use hdf5 enable-hdf5_18)
+		$(cmake-utils_use jpeg enable-jpeg)
+		$(cmake-utils_use mpi enable-mpi)
+		$(cmake-utils_use octave enable-octave)
+		$(cmake-utils_use opengl enable-opengl)
+		$(cmake-utils_use pdf enable-pdf)
+		$(cmake-utils_use png enable-png)
+		$(cmake-utils_use qt4 enable-qt)
+		$(cmake-utils_use threads enable-pthread)
+		$(cmake-utils_use python enable-python)
+		$(cmake-utils_use wxwidgets enable-wx)
+		$(cmake-utils_use zlib enable-zlib)
+	)
+	cmake-utils_src_configure
+	# to whoever cares: TODO: do for multiple python ABI
+	if use python; then
+		sed -i \
+			-e "s:--prefix=\(.*\) :--prefix=\$ENV{DESTDIR}\1 :" \
+			"${CMAKE_BUILD_DIR}"/lang/cmake_install.cmake || die
+		# fix location of numpy
+		use python && append-cppflags \
+			-I$(echo "import numpy; print(numpy.get_include())" | "$(PYTHON)" - 2>/dev/null)
+	fi
+
+}
+
+src_install() {
+	cmake-utils_src_install
+	dodoc README* *.txt AUTHORS
+	use static-libs || rm "${ED}"/usr/$(get_libdir)/*.a
+	if use qt4 ; then
+		local lang
+		insinto /usr/share/udav
+		for lang in ${LANGS} ; do
+			use linguas_${lang} && doins udav/udav_${lang}.qm
+		done
+	fi
+	if use octave ; then
+		insinto /usr/share/${PN}/octave
+		doins "${CMAKE_BUILD_DIR}"/lang/${PN}.tar.gz
+	fi
+}
+
+pkg_postinst() {
+	if use octave; then
+		octave <<-EOF
+		pkg install ${EROOT}/usr/share/${PN}/octave/${PN}.tar.gz
+		EOF
+	fi
+	use python && python_mod_optimize ${PN}.py
+}
+
+pkg_prerm() {
+	if use octave; then
+		octave <<-EOF
+		pkg uninstall ${PN}
+		EOF
+	fi
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup ${PN}.py
+}