Someone wasn't reading the upstream changelogs ... add an option to build the Java GUI.

(Portage version: 2.1.6.13/cvs/Linux x86_64)

2 files changed, 69 insertions, 2 deletions

diff --git a/sci-biology/amap/ChangeLog b/sci-biology/amap/ChangeLog
index fcbb619bae1b..4f44c918c66a 100644
--- a/sci-biology/amap/ChangeLog
+++ b/sci-biology/amap/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-biology/amap
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-biology/amap/ChangeLog,v 1.4 2008/04/17 18:20:13 markusle Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-biology/amap/ChangeLog,v 1.5 2009/07/27 05:52:01 dberkholz Exp $
+
+*amap-2.2-r1 (27 Jul 2009)
+
+  27 Jul 2009; Donnie Berkholz <dberkholz@gentoo.org>; +amap-2.2-r1.ebuild:
+  Someone wasn't reading the upstream changelogs ... add an option to build
+  the Java GUI.
 
 *amap-2.2 (17 Apr 2008)
 
diff --git a/sci-biology/amap/amap-2.2-r1.ebuild b/sci-biology/amap/amap-2.2-r1.ebuild
new file mode 100644
index 000000000000..bef78dab765f
--- /dev/null
+++ b/sci-biology/amap/amap-2.2-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-biology/amap/amap-2.2-r1.ebuild,v 1.1 2009/07/27 05:52:01 dberkholz Exp $
+
+# Java is optional, don't force an ant dependency
+JAVA_ANT_DISABLE_ANT_CORE_DEP="yes"
+
+inherit eutils toolchain-funcs java-pkg-opt-2 java-ant-2
+
+MY_P="${PN}.${PV}"
+DESCRIPTION="Protein multiple-alignment-based sequence annealing"
+HOMEPAGE="http://bio.math.berkeley.edu/amap/"
+SRC_URI="http://baboon.math.berkeley.edu/amap/download/${MY_P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+RDEPEND="
+	java? (
+		>=virtual/jre-1.5
+	)"
+DEPEND="${RDEPEND}
+	java? (
+		>=dev-java/ant-core-1.7.0
+		>=dev-java/javatoolkit-0.3.0-r2
+		>=virtual/jdk-1.5
+	)"
+S="${WORKDIR}/${PN}-align"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/${P}-cxxflags.patch
+	epatch "${FILESDIR}"/${P}-gcc4.3.patch
+}
+
+src_compile() {
+	pushd "${S}"/align
+	emake \
+		CXX="$(tc-getCXX)" \
+		OPT_CXXFLAGS="${CXXFLAGS}" \
+		|| die "make failed"
+	popd
+
+	if use java; then
+		pushd "${S}"/display
+		eant all || die
+		popd
+	fi
+}
+
+src_install() {
+	dobin align/${PN}
+	dodoc align/README align/PROBCONS.README
+	insinto /usr/share/${PN}/examples
+	doins examples/* || die "Failed to install examples"
+	if use java; then
+		java-pkg_newjar "${S}"/display/AmapDisplay.jar amapdisplay.jar
+		java-pkg_dolauncher amapdisplay --jar amapdisplay.jar
+	fi
+}