Install pcmcia udev rules and the helper to right directories. Fixes bug #178671.

(Portage version: 2.1.2.7)

3 files changed, 108 insertions, 1 deletions

diff --git a/net-wireless/bluez-utils/ChangeLog b/net-wireless/bluez-utils/ChangeLog
index 0e98bfafb73e..c433e61258da 100644
--- a/net-wireless/bluez-utils/ChangeLog
+++ b/net-wireless/bluez-utils/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-wireless/bluez-utils
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez-utils/ChangeLog,v 1.90 2007/05/12 14:53:28 betelgeuse Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez-utils/ChangeLog,v 1.91 2007/05/16 09:51:54 betelgeuse Exp $
+
+*bluez-utils-3.10-r2 (16 May 2007)
+
+  16 May 2007; Petteri Räty <betelgeuse@gentoo.org>
+  +bluez-utils-3.10-r2.ebuild:
+  Install pcmcia udev rules and the helper to right directories. Fixes bug
+  #178671.
 
   12 May 2007; Petteri Räty <betelgeuse@gentoo.org> metadata.xml:
   Add Dick Marinus <dm@chello.nl> as a proxy maintainer to metadata.xml.
diff --git a/net-wireless/bluez-utils/bluez-utils-3.10-r2.ebuild b/net-wireless/bluez-utils/bluez-utils-3.10-r2.ebuild
new file mode 100644
index 000000000000..6c9d8e7936a3
--- /dev/null
+++ b/net-wireless/bluez-utils/bluez-utils-3.10-r2.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez-utils/bluez-utils-3.10-r2.ebuild,v 1.1 2007/05/16 09:51:54 betelgeuse Exp $
+
+inherit eutils
+
+DESCRIPTION="Bluetooth Tools and System Daemons for Linux"
+HOMEPAGE="http://bluez.sourceforge.net/"
+SRC_URI="http://bluez.sourceforge.net/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+
+IUSE="alsa debug hal usb cups"
+
+DEPEND="app-pda/libopensync
+	>=net-wireless/bluez-libs-3.10
+	hal? ( sys-apps/hal )
+	usb? ( dev-libs/libusb )
+	cups? ( net-print/cups )
+	sys-fs/udev
+	dev-libs/glib
+	sys-apps/dbus"
+
+src_unpack() {
+	unpack ${A}
+	# bundled glib
+	cd "${S}"
+	rm -r eglib/{*.c,*.h}  || die
+}
+
+src_compile() {
+	econf \
+		$(use_enable alsa audio) \
+		$(use_enable alsa) \
+		$(use_enable debug) \
+		$(use_enable usb) \
+		$(use_enable cups) \
+		$(use_enable hal) \
+		--enable-glib  \
+		--enable-inotify \
+		--enable-obex \
+		--enable-input \
+		--enable-sync \
+		--enable-hcid \
+		--enable-sdpd \
+		--enable-hidd \
+		--enable-configfiles \
+		--disable-initscripts \
+		--disable-pcmciarules \
+		--enable-bccmd \
+		--enable-avctrl \
+		--enable-hid2hci \
+		--enable-dfutool \
+		--localstatedir=/var \
+		|| die "econf failed"
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "make install failed"
+
+	dodoc AUTHORS ChangeLog README || die
+
+	# optional bluetooth utils
+	dosbin tools/hcisecfilter tools/ppporc
+	dobin daemon/passkey-agent
+
+	newinitd "${FILESDIR}/${PN}-3.10-init.d" bluetooth || die
+	newconfd "${S}/scripts/bluetooth.default" bluetooth || die
+
+	# bug #84431
+	insinto /etc/udev/rules.d/
+	newins "${FILESDIR}/${PN}-2.24-udev.rules" 70-bluetooth.rules || die
+	newins "${S}/scripts/bluetooth.rules" 70-bluetooth-pcmcia.rules || die
+
+	exeinto /lib/udev/
+	newexe "${FILESDIR}/${PN}-2.24-udev.script" bluetooth.sh || die
+	doexe  "${S}/scripts/bluetooth_serial" || die
+}
+
+pkg_postinst() {
+	udevcontrol reload_rules && udevtrigger
+
+	elog "If you use hidd, add --encrypt to the HIDD_OPTIONS in"
+	elog "/etc/conf.d/bluetooth to secure your connection"
+	elog
+	elog "To use dund you must install net-dialup/ppp"
+	elog ""
+	elog "Since 3.0 bluez has changed the passkey handling to use a dbus based"
+	elog "API so please remember to update your /etc/bluetooth/hcid.conf."
+	elog "For a password asking program, there is for example"
+	elog "net-wireless/bluez-gnome for gnome and net-wireless/kdebluetooth"
+	elog "for kde."
+}
diff --git a/net-wireless/bluez-utils/files/digest-bluez-utils-3.10-r2 b/net-wireless/bluez-utils/files/digest-bluez-utils-3.10-r2
new file mode 100644
index 000000000000..1f2a8007cdfe
--- /dev/null
+++ b/net-wireless/bluez-utils/files/digest-bluez-utils-3.10-r2
@@ -0,0 +1,3 @@
+MD5 8ad55638a65cb483cbe2717ef3ea7a01 bluez-utils-3.10.tar.gz 802676
+RMD160 12a0d419535a20be5df5afb65134b13a196bc962 bluez-utils-3.10.tar.gz 802676
+SHA256 37c02eeb26cf59e9252e423c9326beaaff61f25bc5186b7f5ce3faacd6a8bc89 bluez-utils-3.10.tar.gz 802676