new beta release

(Portage version: 2.1.11.62/cvs/Linux x86_64, signed Manifest commit with key DD11F94A)

3 files changed, 110 insertions, 5 deletions

diff --git a/net-wireless/aircrack-ng/ChangeLog b/net-wireless/aircrack-ng/ChangeLog
index 458535e7468b..5105078dc1be 100644
--- a/net-wireless/aircrack-ng/ChangeLog
+++ b/net-wireless/aircrack-ng/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-wireless/aircrack-ng
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/ChangeLog,v 1.75 2013/05/26 02:42:39 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/ChangeLog,v 1.76 2013/05/26 05:11:10 zerochaos Exp $
+
+*aircrack-ng-1.2_beta1 (26 May 2013)
+
+  26 May 2013; Rick Farina <zerochaos@gentoo.org> +aircrack-ng-1.2_beta1.ebuild,
+  aircrack-ng-9999.ebuild:
+  new beta release
 
   26 May 2013; Rick Farina <zerochaos@gentoo.org> aircrack-ng-9999.ebuild:
   fixing for new svn location, and unhijacking the misguided
diff --git a/net-wireless/aircrack-ng/aircrack-ng-1.2_beta1.ebuild b/net-wireless/aircrack-ng/aircrack-ng-1.2_beta1.ebuild
new file mode 100644
index 000000000000..7bce9729fd69
--- /dev/null
+++ b/net-wireless/aircrack-ng/aircrack-ng-1.2_beta1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-1.2_beta1.ebuild,v 1.1 2013/05/26 05:11:10 zerochaos Exp $
+
+EAPI="5"
+
+inherit toolchain-funcs versionator
+
+DESCRIPTION="WLAN tools for breaking 802.11 WEP/WPA keys"
+HOMEPAGE="http://www.aircrack-ng.org"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit subversion
+	ESVN_REPO_URI="http://svn.aircrack-ng.org/trunk"
+	KEYWORDS=""
+else
+	MY_PV="$(replace_version_separator 2 '-')"
+	SRC_URI="http://download.aircrack-ng.org/${PN}-${MY_PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="+airdrop-ng +airgraph-ng kernel_linux kernel_FreeBSD netlink +sqlite +unstable"
+
+DEPEND="dev-libs/openssl
+	netlink? ( dev-libs/libnl:3 )
+	sqlite? ( >=dev-db/sqlite-3.4 )"
+RDEPEND="${DEPEND}
+	kernel_linux? (
+		net-wireless/iw
+		net-wireless/wireless-tools
+		sys-apps/ethtool
+		sys-apps/usbutils
+		sys-apps/pciutils )
+	sys-apps/hwids
+	airdrop-ng? ( net-wireless/lorcon[python] )"
+
+S="${WORKDIR}/${PN}"
+
+src_compile() {
+	emake \
+	CC="$(tc-getCC)" \
+	AR="$(tc-getAR)" \
+	LD="$(tc-getLD)" \
+	RANLIB="$(tc-getRANLIB)" \
+	libnl=$(usex netlink true false) \
+	sqlite=$(usex sqlite true false) \
+	unstable=$(usex unstable true false) \
+	REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}"
+}
+
+src_install() {
+	emake \
+		prefix="${ED}/usr" \
+		libnl=$(usex netlink true false) \
+		sqlite=$(usex sqlite true false) \
+		unstable=$(usex unstable true false) \
+		REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}" \
+		install
+
+	dodoc AUTHORS ChangeLog INSTALLING README
+
+	if use airgraph-ng; then
+		cd "${S}/scripts/airgraph-ng"
+		emake prefix="${ED}/usr" install
+	fi
+	if use airdrop-ng; then
+		cd "${S}/scripts/airdrop-ng"
+		emake prefix="${ED}/usr" install
+	fi
+
+	#we don't need aircrack-ng's oui updater, we have our own
+	rm "${ED}"/usr/sbin/airodump-ng-oui-update
+}
+
+pkg_postinst() {
+	# Message is (c) FreeBSD
+	# http://www.freebsd.org/cgi/cvsweb.cgi/ports/net-mgmt/aircrack-ng/files/pkg-message.in?rev=1.5
+	if use kernel_FreeBSD ; then
+		einfo "Contrary to Linux, it is not necessary to use airmon-ng to enable the monitor"
+		einfo "mode of your wireless card.  So do not care about what the manpages say about"
+		einfo "airmon-ng, airodump-ng sets monitor mode automatically."
+		echo
+		einfo "To return from monitor mode, issue the following command:"
+		einfo "    ifconfig \${INTERFACE} -mediaopt monitor"
+		einfo
+		einfo "For aireplay-ng you need FreeBSD >= 7.0."
+	fi
+}
diff --git a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
index 3b05ba755f9c..3952b48848dd 100644
--- a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
+++ b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
@@ -1,18 +1,26 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild,v 1.4 2013/05/26 02:42:39 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild,v 1.5 2013/05/26 05:11:10 zerochaos Exp $
 
 EAPI="5"
 
-inherit toolchain-funcs versionator subversion
+inherit toolchain-funcs versionator
 
 DESCRIPTION="WLAN tools for breaking 802.11 WEP/WPA keys"
 HOMEPAGE="http://www.aircrack-ng.org"
-ESVN_REPO_URI="http://svn.aircrack-ng.org/trunk"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit subversion
+	ESVN_REPO_URI="http://svn.aircrack-ng.org/trunk"
+	KEYWORDS=""
+else
+	MY_PV="$(replace_version_separator 2 '-')"
+	SRC_URI="http://download.aircrack-ng.org/${PN}-${MY_PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+fi
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS=""
 
 IUSE="+airdrop-ng +airgraph-ng kernel_linux kernel_FreeBSD netlink +sqlite +unstable"