Version bump to 0.15.2. Changed LINGUAS and removed no longer needed sqlite dependency. Proxied commit for Nikoli.

(Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

3 files changed, 63 insertions, 3 deletions

diff --git a/net-news/quiterss/ChangeLog b/net-news/quiterss/ChangeLog
index f0d07499c75e..a0c5fcc10f79 100644
--- a/net-news/quiterss/ChangeLog
+++ b/net-news/quiterss/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-news/quiterss
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-news/quiterss/ChangeLog,v 1.39 2014/02/14 12:34:54 maksbotan Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-news/quiterss/ChangeLog,v 1.40 2014/04/05 19:21:18 tomwij Exp $
+
+*quiterss-0.15.2 (05 Apr 2014)
+
+  05 Apr 2014; Tom Wijsman <TomWij@gentoo.org> +quiterss-0.15.2.ebuild,
+  quiterss-9999.ebuild:
+  Version bump to 0.15.2. Changed LINGUAS and removed no longer needed sqlite
+  dependency. Proxied commit for Nikoli.
 
   14 Feb 2014; Maxim Koltsov <maksbotan@gentoo.org> quiterss-9999.ebuild:
   Update PLOCALES in 9999, thanks to Nikoli
diff --git a/net-news/quiterss/quiterss-0.15.2.ebuild b/net-news/quiterss/quiterss-0.15.2.ebuild
new file mode 100644
index 000000000000..8c5b730f9f86
--- /dev/null
+++ b/net-news/quiterss/quiterss-0.15.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-news/quiterss/quiterss-0.15.2.ebuild,v 1.1 2014/04/05 19:21:18 tomwij Exp $
+
+EAPI=5
+
+PLOCALES="ar cs de el_GR es fa fi fr gl hu it ja ko lt nl pl pt_BR pt_PT ro_RO ru sk sr sv tg_TJ tr uk vi zh_CN zh_TW"
+inherit l10n qt4-r2
+
+MY_P="QuiteRSS-${PV}-src"
+
+DESCRIPTION="A Qt4-based RSS/Atom feed reader"
+HOMEPAGE="https://quiterss.org"
+SRC_URI="https://quiterss.org/files/${PV}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug phonon"
+
+RDEPEND="
+	dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	dev-qt/qtsingleapplication
+	dev-qt/qtsql:4[sqlite]
+	dev-qt/qtwebkit:4
+	phonon? ( || ( media-libs/phonon dev-qt/qtphonon:4 ) )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( AUTHORS HISTORY_EN HISTORY_RU README )
+
+src_prepare() {
+	my_rm_loc() {
+		sed -i -e "s:lang/${PN}_${1}.ts::" lang/lang.pri || die 'sed on lang.pri failed'
+	}
+	# dedicated english locale file is not installed at all
+	rm "lang/${PN}_en.ts" || die "remove of lang/${PN}_en.ts failed"
+
+	l10n_find_plocales_changes "lang" "${PN}_" '.ts'
+	l10n_for_each_disabled_locale_do my_rm_loc
+
+	qt4-r2_src_prepare
+}
+
+src_configure() {
+	eqmake4 PREFIX="${EPREFIX}/usr" \
+		SYSTEMQTSA=1 \
+		$(usex phonon '' 'DISABLE_PHONON=1')
+}
diff --git a/net-news/quiterss/quiterss-9999.ebuild b/net-news/quiterss/quiterss-9999.ebuild
index bbb1e4752373..9ea3fd562375 100644
--- a/net-news/quiterss/quiterss-9999.ebuild
+++ b/net-news/quiterss/quiterss-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-news/quiterss/quiterss-9999.ebuild,v 1.15 2014/02/14 12:34:54 maksbotan Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-news/quiterss/quiterss-9999.ebuild,v 1.16 2014/04/05 19:21:18 tomwij Exp $
 
 EAPI=5
 
@@ -17,7 +17,6 @@ KEYWORDS=""
 IUSE="debug phonon"
 
 RDEPEND="
-	dev-db/sqlite:3
 	dev-qt/qtcore:4
 	dev-qt/qtgui:4
 	dev-qt/qtsingleapplication