tlsdate various small fixes

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key BBB51E42)

2 files changed, 75 insertions, 2 deletions

diff --git a/net-misc/tlsdate/ChangeLog b/net-misc/tlsdate/ChangeLog
index 96e8e83c9399..b57ed19a1090 100644
--- a/net-misc/tlsdate/ChangeLog
+++ b/net-misc/tlsdate/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/tlsdate
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/tlsdate/ChangeLog,v 1.11 2014/11/06 16:00:28 vapier Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/tlsdate/ChangeLog,v 1.12 2015/01/03 00:29:06 hanno Exp $
+
+*tlsdate-0.0.12-r1 (03 Jan 2015)
+
+  03 Jan 2015; <hanno@gentoo.org> +tlsdate-0.0.12-r1.ebuild:
+  Fix default server/config, disable polarssl (broken upstream), install dbus
+  rules.
 
 *tlsdate-0.0.12 (06 Nov 2014)
 
diff --git a/net-misc/tlsdate/tlsdate-0.0.12-r1.ebuild b/net-misc/tlsdate/tlsdate-0.0.12-r1.ebuild
new file mode 100644
index 000000000000..6f8f1d2e47fa
--- /dev/null
+++ b/net-misc/tlsdate/tlsdate-0.0.12-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/tlsdate/tlsdate-0.0.12-r1.ebuild,v 1.1 2015/01/03 00:29:06 hanno Exp $
+
+EAPI="4"
+
+inherit autotools vcs-snapshot user
+
+DESCRIPTION="Update local time over HTTPS"
+HOMEPAGE="https://github.com/ioerror/tlsdate"
+SRC_URI="https://github.com/ioerror/tlsdate/tarball/${P} -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="dbus +seccomp static-libs"
+
+DEPEND="dev-libs/openssl
+	dev-libs/libevent
+	dbus? ( sys-apps/dbus )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# Use Google servers by default rather than a random German site.
+	# They provide round robin DNS and local servers automatically.
+	sed -i \
+		-e 's:www.ptb.de:www.google.com:' \
+		etc/tlsdated.conf \
+		src/tlsdate.h || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable dbus) \
+		$(use_enable seccomp seccomp-filter) \
+		--disable-hardened-checks \
+		--without-polarssl \
+		--with-unpriv-user=tlsdate \
+		--with-unpriv-group=tlsdate
+}
+
+src_install() {
+	default
+
+	# only install cert required for www.google.com
+	rm "${ED}"/etc/tlsdate/ca-roots/tlsdate-ca-roots.conf || die #446426
+	dosym "${EPREFIX}"/etc/ssl/certs/Equifax_Secure_CA.pem \
+		/etc/tlsdate/ca-roots/tlsdate-ca-roots.conf
+
+	newinitd "${FILESDIR}"/tlsdated.rc tlsdated
+	newconfd "${FILESDIR}"/tlsdated.confd tlsdated
+	newinitd "${FILESDIR}"/tlsdate.rc tlsdate
+	newconfd "${FILESDIR}"/tlsdate.confd tlsdate
+
+	insinto /etc/dbus-1/system.d/
+	doins dbus/org.torproject.tlsdate.conf
+
+	use static-libs || \
+		find "${ED}"/usr '(' -name '*.la' -o -name '*.a' ')' -delete
+}
+
+pkg_preinst() {
+	enewgroup tlsdate 124
+	enewuser tlsdate 124 -1 /dev/null tlsdate
+}