Version bump.

(Portage version: 2.2.0_alpha90/cvs/Linux x86_64)

2 files changed, 116 insertions, 1 deletions

diff --git a/net-libs/gnutls/ChangeLog b/net-libs/gnutls/ChangeLog
index 602ed48ea43a..57a3fff5458b 100644
--- a/net-libs/gnutls/ChangeLog
+++ b/net-libs/gnutls/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/gnutls
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.338 2012/03/16 22:49:41 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.339 2012/03/16 23:02:06 radhermit Exp $
+
+*gnutls-3.0.16 (16 Mar 2012)
+
+  16 Mar 2012; Tim Harder <radhermit@gentoo.org> +gnutls-3.0.16.ebuild:
+  Version bump.
 
 *gnutls-2.12.18 (16 Mar 2012)
 
diff --git a/net-libs/gnutls/gnutls-3.0.16.ebuild b/net-libs/gnutls/gnutls-3.0.16.ebuild
new file mode 100644
index 000000000000..80ded92e59cf
--- /dev/null
+++ b/net-libs/gnutls/gnutls-3.0.16.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-3.0.16.ebuild,v 1.1 2012/03/16 23:02:06 radhermit Exp $
+
+EAPI=4
+
+inherit autotools libtool eutils
+
+DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
+HOMEPAGE="http://www.gnutls.org/"
+
+if [[ "${PV}" == *pre* ]]; then
+	SRC_URI="http://daily.josefsson.org/${P%.*}/${P%.*}-${PV#*pre}.tar.gz"
+else
+	MINOR_VERSION="${PV#*.}"
+	MINOR_VERSION="${MINOR_VERSION%%.*}"
+	if [[ $((MINOR_VERSION % 2)) == 0 ]]; then
+		#SRC_URI="ftp://ftp.gnu.org/pub/gnu/${PN}/${P}.tar.bz2"
+		SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
+	else
+		SRC_URI="ftp://alpha.gnu.org/gnu/${PN}/${P}.tar.xz"
+	fi
+	unset MINOR_VERSION
+fi
+
+# LGPL-2.1 for libgnutls library and GPL-3 for libgnutls-extra library.
+LICENSE="GPL-3 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="+cxx doc examples guile nls pkcs11 static-libs test zlib"
+
+RDEPEND=">=dev-libs/libtasn1-0.3.4
+	>=dev-libs/nettle-2.4[gmp]
+	>=sys-devel/autogen-5.15
+	guile? ( >=dev-scheme/guile-1.8[networking] )
+	nls? ( virtual/libintl )
+	pkcs11? ( >=app-crypt/p11-kit-0.11 )
+	zlib? ( >=sys-libs/zlib-1.2.3.1 )"
+DEPEND="${RDEPEND}
+	sys-devel/libtool
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )
+	test? ( app-misc/datefudge )"
+
+S="${WORKDIR}/${P%_pre*}"
+
+DOCS=( AUTHORS ChangeLog NEWS README THANKS doc/TODO )
+
+src_prepare() {
+	local dir
+
+	# tests/suite directory is not distributed.
+	sed -i \
+		-e ':AC_CONFIG_FILES(\[tests/suite/Makefile\]):d' \
+		configure.ac || die
+
+	sed -i \
+		-e 's/imagesdir = $(infodir)/imagesdir = $(htmldir)/' \
+		doc/Makefile.am || die
+
+	for dir in m4 gl/m4; do
+		rm -f "${dir}/lt"* "${dir}/libtool.m4"
+	done
+	find . -name ltmain.sh -exec rm {} \;
+
+	# force regeneration of autogen-ed files
+	for i in $(grep -l AutoGen-ed src/*.c) ; do
+		rm src/$(basename ${i} .c).{c,h} || die
+	done
+
+	# support user patches
+	epatch_user
+
+	eautoreconf
+
+	# Use sane .so versioning on FreeBSD.
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		--htmldir="${EPREFIX}/usr/share/doc/${PF}/html" \
+		--disable-local-libopts \
+		--disable-valgrind-tests \
+		$(use_enable cxx) \
+		$(use_enable doc gtk-doc) \
+		$(use_enable doc gtk-doc-pdf) \
+		$(use_enable guile) \
+		$(use_enable nls) \
+		$(use_enable static-libs static) \
+		$(use_with pkcs11 p11-kit) \
+		$(use_with zlib) \
+		${myconf}
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+
+	if use doc; then
+		dodoc doc/gnutls.{pdf,ps}
+		dohtml doc/gnutls.html
+	fi
+
+	if use examples; then
+		docinto examples
+		dodoc doc/examples/*.c
+	fi
+}