Version bump, bug #509932

(Portage version: 2.2.7/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 55 insertions, 2 deletions

diff --git a/net-libs/libtorrent/ChangeLog b/net-libs/libtorrent/ChangeLog
index 26219456d551..b057d1d7018f 100644
--- a/net-libs/libtorrent/ChangeLog
+++ b/net-libs/libtorrent/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libtorrent
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libtorrent/ChangeLog,v 1.173 2013/03/22 08:28:17 patrick Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libtorrent/ChangeLog,v 1.174 2014/06/10 12:24:53 vostorga Exp $
+
+*libtorrent-0.13.4 (10 Jun 2014)
+
+  10 Jun 2014; Victor Ostorga <vostorga@gentoo.org> +libtorrent-0.13.4.ebuild:
+  Version bump, bug #509932
 
 *libtorrent-0.13.3 (22 Mar 2013)
 
diff --git a/net-libs/libtorrent/libtorrent-0.13.4.ebuild b/net-libs/libtorrent/libtorrent-0.13.4.ebuild
new file mode 100644
index 000000000000..11f2ea9fcb2f
--- /dev/null
+++ b/net-libs/libtorrent/libtorrent-0.13.4.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libtorrent/libtorrent-0.13.4.ebuild,v 1.1 2014/06/10 12:24:53 vostorga Exp $
+
+EAPI=4
+
+inherit eutils libtool toolchain-funcs
+
+DESCRIPTION="BitTorrent library written in C++ for *nix"
+HOMEPAGE="http://libtorrent.rakshasa.no/"
+SRC_URI="http://libtorrent.rakshasa.no/downloads/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris"
+IUSE="debug ipv6 ssl"
+
+RDEPEND="
+	>=dev-libs/libsigc++-2.2.2:2
+	ssl? ( dev-libs/openssl )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+#	epatch "${FILESDIR}"/download_constructor.diff
+	elibtoolize
+}
+
+src_configure() {
+	# the configure check for posix_fallocate is wrong.
+	# reported upstream as Ticket 2416.
+	local myconf
+	echo "int main(){return posix_fallocate();}" > "${T}"/posix_fallocate.c
+	if $(tc-getCC) ${CFLAGS} ${LDFLAGS} "${T}"/posix_fallocate.c -o /dev/null 2>/dev/null ; then
+		myconf="--with-posix-fallocate"
+	else
+		myconf="--without-posix-fallocate"
+	fi
+
+	# configure needs bash or script bombs out on some null shift, bug #291229
+	CONFIG_SHELL=${BASH} econf \
+		--disable-dependency-tracking \
+		--enable-aligned \
+		$(use_enable debug) \
+		$(use_enable ipv6) \
+		$(use_enable ssl openssl) \
+		${myconf}
+}