Version bump

(Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

2 files changed, 86 insertions, 1 deletions

diff --git a/net-libs/libssh/ChangeLog b/net-libs/libssh/ChangeLog
index 8a18587ae63e..ebfc3cb39e3d 100644
--- a/net-libs/libssh/ChangeLog
+++ b/net-libs/libssh/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libssh
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/ChangeLog,v 1.95 2014/01/06 13:35:00 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/ChangeLog,v 1.96 2014/01/08 12:29:58 polynomial-c Exp $
+
+*libssh-0.6.0 (08 Jan 2014)
+
+  08 Jan 2014; Lars Wendler <polynomial-c@gentoo.org> +libssh-0.6.0.ebuild:
+  Version bump.
 
 *libssh-0.6.0_rc3-r1 (06 Jan 2014)
 
diff --git a/net-libs/libssh/libssh-0.6.0.ebuild b/net-libs/libssh/libssh-0.6.0.ebuild
new file mode 100644
index 000000000000..377ba76a9cd7
--- /dev/null
+++ b/net-libs/libssh/libssh-0.6.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/libssh-0.6.0.ebuild,v 1.1 2014/01/08 12:29:58 polynomial-c Exp $
+
+EAPI=5
+
+MY_P=${PN}-${PV/_rc/rc}
+inherit eutils cmake-utils multilib
+
+DESCRIPTION="Access a working SSH implementation by means of a library"
+HOMEPAGE="http://www.libssh.org/"
+SRC_URI="https://red.libssh.org/attachments/download/71/${MY_P}.tar.xz -> ${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+KEYWORDS="~amd64 ~arm ~hppa ~x86 ~amd64-linux ~x86-linux"
+SLOT="0/4" # subslot = soname major version
+IUSE="debug doc examples pcap +sftp ssh1 server static-libs test zlib"
+# Maintainer: check IUSE-defaults at DefineOptions.cmake
+
+RDEPEND="
+	zlib? ( >=sys-libs/zlib-1.2 )
+	>=dev-libs/openssl-0.9.8
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cmocka )
+"
+
+DOCS=( AUTHORS README ChangeLog )
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.5.0-tests.patch"
+)
+
+src_prepare() {
+	# just install the examples do not compile them
+	sed -i \
+		-e '/add_subdirectory(examples)/s/^/#DONOTWANT/' \
+		CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with debug DEBUG_CALLTRACE)
+		$(cmake-utils_use_with debug DEBUG_CRYPTO)
+		$(cmake-utils_use_with pcap)
+		$(cmake-utils_use_with server)
+		$(cmake-utils_use_with sftp)
+		$(cmake-utils_use_with ssh1)
+		$(cmake-utils_use_with static-libs STATIC_LIB)
+		$(cmake-utils_use_with test STATIC_LIB)
+		$(cmake-utils_use_with test TESTING)
+		$(cmake-utils_use_with zlib)
+		-DWITH_GCRYPT=OFF
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	use doc && cmake-utils_src_compile doc
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use doc && dohtml -r "${CMAKE_BUILD_DIR}"/doc/html/*
+
+	use static-libs || rm -f "${D}"/usr/$(get_libdir)/libssh{,_threads}.a
+
+	if use examples; then
+		docinto examples
+		dodoc examples/*.{c,h,cpp}
+	fi
+}