Add multilib support (bug #524604 by Arfrever Frehtes Taifersar Arahesis).

(Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key A792A613)

2 files changed, 75 insertions, 1 deletions

diff --git a/net-libs/libpcap/ChangeLog b/net-libs/libpcap/ChangeLog
index 2b1590803860..fe571e1312aa 100644
--- a/net-libs/libpcap/ChangeLog
+++ b/net-libs/libpcap/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libpcap
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libpcap/ChangeLog,v 1.209 2014/09/17 10:14:57 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libpcap/ChangeLog,v 1.210 2014/10/07 09:18:26 jer Exp $
+
+*libpcap-1.6.2-r1 (07 Oct 2014)
+
+  07 Oct 2014; Jeroen Roovers <jer@gentoo.org> +libpcap-1.6.2-r1.ebuild:
+  Add multilib support (bug #524604 by Arfrever Frehtes Taifersar Arahesis).
 
   17 Sep 2014; Jeroen Roovers <jer@gentoo.org>
   files/libpcap-1.2.0-cross-linux.patch:
diff --git a/net-libs/libpcap/libpcap-1.6.2-r1.ebuild b/net-libs/libpcap/libpcap-1.6.2-r1.ebuild
new file mode 100644
index 000000000000..b46321b68da3
--- /dev/null
+++ b/net-libs/libpcap/libpcap-1.6.2-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libpcap/libpcap-1.6.2-r1.ebuild,v 1.1 2014/10/07 09:18:26 jer Exp $
+
+EAPI=5
+inherit autotools eutils multilib-minimal
+
+DESCRIPTION="A system-independent library for user-level network packet capture"
+HOMEPAGE="http://www.tcpdump.org/"
+SRC_URI="http://www.tcpdump.org/release/${P}.tar.gz
+	http://www.jp.tcpdump.org/release/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="bluetooth dbus ipv6 netlink static-libs canusb"
+
+RDEPEND="
+	bluetooth? ( net-wireless/bluez:=[${MULTILIB_USEDEP}] )
+	dbus? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
+	netlink? ( dev-libs/libnl:3[${MULTILIB_USEDEP}] )
+	canusb? ( virtual/libusb:1[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	virtual/yacc
+	dbus? ( virtual/pkgconfig[${MULTILIB_USEDEP}] )
+"
+
+DOCS=( CREDITS CHANGES VERSION TODO README{,.dag,.linux,.macosx,.septel} )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.2.0-cross-linux.patch
+	epatch "${FILESDIR}"/${PN}-1.6.1-configure.patch
+	epatch "${FILESDIR}"/${PN}-1.6.1-prefix-solaris.patch
+
+	mkdir bluetooth || die
+	cp "${FILESDIR}"/mgmt.h bluetooth/ || die
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" \
+	econf \
+		$(use_enable bluetooth) \
+		$(use_enable ipv6) \
+		$(use_enable canusb) \
+		$(use_enable dbus) \
+		$(use_with netlink libnl)
+}
+
+multilib_src_compile() {
+	emake all shared
+}
+
+multilib_src_install_all() {
+	# remove static libraries (--disable-static does not work)
+	if ! use static-libs; then
+		find "${ED}" -name '*.a' -exec rm {} + || die
+	fi
+	prune_libtool_files
+
+	# We need this to build pppd on G/FBSD systems
+	if [[ "${USERLAND}" == "BSD" ]]; then
+		insinto /usr/include
+		doins pcap-int.h
+	fi
+}