Version bump, bug #349644

(Portage version: 2.1.9.25/cvs/Linux x86_64)

2 files changed, 85 insertions, 2 deletions

diff --git a/net-im/amsn/ChangeLog b/net-im/amsn/ChangeLog
index a2a294ae167f..8fb870506c1e 100644
--- a/net-im/amsn/ChangeLog
+++ b/net-im/amsn/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/amsn
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/amsn/ChangeLog,v 1.100 2010/10/15 22:00:57 ranger Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/amsn/ChangeLog,v 1.101 2011/01/30 20:59:49 tester Exp $
+
+*amsn-0.98.4 (30 Jan 2011)
+
+  30 Jan 2011; Olivier Crête <tester@gentoo.org> +amsn-0.98.4.ebuild:
+  Version bump, bug #349644
 
   15 Oct 2010; Brent Baude <ranger@gentoo.org> amsn-0.98.3.ebuild:
   stable ppc, bug 327379
diff --git a/net-im/amsn/amsn-0.98.4.ebuild b/net-im/amsn/amsn-0.98.4.ebuild
new file mode 100644
index 000000000000..bd2b4cd852a5
--- /dev/null
+++ b/net-im/amsn/amsn-0.98.4.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/amsn/amsn-0.98.4.ebuild,v 1.1 2011/01/30 20:59:49 tester Exp $
+
+EAPI=2
+
+inherit eutils fdo-mime gnome2-utils
+
+MY_P=${P/_rc/RC}
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="aMSN Messenger client"
+SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${MY_P}-src.tar.bz2"
+HOMEPAGE="http://www.amsn-project.net"
+
+# The tests are interactive
+RESTRICT="test"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc -sparc ~x86"
+IUSE="debug"
+
+DEPEND=">=dev-lang/tcl-8.4
+	>=dev-lang/tk-8.4
+	media-libs/jpeg
+	media-libs/libpng
+	>=dev-tcltk/snack-2.2.10
+	>=net-libs/gupnp-igd-0.1.3
+	media-libs/libv4l"
+#	>=net-libs/farsight2-0.0.14
+#	>=media-libs/gstreamer-0.10.23
+#	>=media-libs/gst-plugins-base-0.10.23
+
+RDEPEND="${DEPEND}
+	>=dev-tcltk/tls-1.5
+	media-video/ffmpeg[encode]"
+#	>=media-libs/gst-plugins-good-0.10.15
+#	>=media-libs/gst-plugins-bad-0.10.13
+#	>=media-plugins/gst-plugins-ffmpeg-0.10.7
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-0.98-noautoupdate.patch"
+	# only portage should strip files, bug 285682
+	sed -i -e "s/LDFLAGS += -s/LDFLAGS += /" Makefile.in || die "sed failed"
+}
+
+src_configure() {
+	econf $(use_enable debug) || die "configure script failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die
+	dodoc AGREEMENT TODO README FAQ CREDITS
+
+	domenu amsn.desktop
+	sed -i -e s:.png:: "${D}/usr/share/applications/amsn.desktop"
+
+	cd desktop-icons
+	for i in *; do
+		if [ -e ${i}/msn.png ]; then
+			insinto /usr/share/icons/hicolor/${i}/apps
+			doins  ${i}/msn.png
+		fi
+	done
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+
+	ewarn "You might have to remove ~/.amsn prior to running as user if amsn hangs on start-up."
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}