Version bump.

(Portage version: 2.2_rc33/cvs/Linux i686)

2 files changed, 73 insertions, 1 deletions

diff --git a/net-ftp/lftp/ChangeLog b/net-ftp/lftp/ChangeLog
index af9cb0004a28..b09e61eb1935 100644
--- a/net-ftp/lftp/ChangeLog
+++ b/net-ftp/lftp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-ftp/lftp
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.210 2009/07/29 05:05:15 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.211 2009/07/30 17:20:51 jer Exp $
+
+*lftp-3.99.6 (30 Jul 2009)
+
+  30 Jul 2009; Jeroen Roovers <jer@gentoo.org> +lftp-3.99.6.ebuild:
+  Version bump.
 
   29 Jul 2009; Jeroen Roovers <jer@gentoo.org> lftp-3.99.5.ebuild,
   +files/lftp-3.99.5-torrent_la.patch:
diff --git a/net-ftp/lftp/lftp-3.99.6.ebuild b/net-ftp/lftp/lftp-3.99.6.ebuild
new file mode 100644
index 000000000000..eabf6a242c06
--- /dev/null
+++ b/net-ftp/lftp/lftp-3.99.6.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/lftp-3.99.6.ebuild,v 1.1 2009/07/30 17:20:51 jer Exp $
+
+EAPI="2"
+
+inherit eutils autotools
+
+DESCRIPTION="A sophisticated ftp/sftp/http/https client and file transfer program"
+HOMEPAGE="http://lftp.yar.ru/"
+SRC_URI="ftp://ftp.yar.ru/lftp/devel/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="ssl gnutls socks5 nls"
+
+RDEPEND=">=sys-libs/ncurses-5.1
+		socks5? (
+			>=net-proxy/dante-1.1.12
+			virtual/pam )
+		ssl? (
+			gnutls? ( >=net-libs/gnutls-1.2.3 )
+			!gnutls? ( >=dev-libs/openssl-0.9.6 )
+		)
+		virtual/libc
+		>=sys-libs/readline-5.1"
+
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+	dev-lang/perl
+	=sys-devel/libtool-2*
+"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-gnutls.patch"
+	epatch "${FILESDIR}/${PN}-3.99.5-torrent_la.patch"
+	eautoreconf
+}
+
+src_configure() {
+	local myconf="$(use_enable nls) --enable-packager-mode"
+
+	if use ssl && use gnutls ; then
+		myconf="${myconf} --without-openssl"
+	elif use ssl && ! use gnutls ; then
+		myconf="${myconf} --without-gnutls --with-openssl=/usr"
+	else
+		myconf="${myconf} --without-gnutls --without-openssl"
+	fi
+
+	use socks5 && myconf="${myconf} --with-socksdante=/usr" \
+		|| myconf="${myconf} --without-socksdante"
+
+	econf \
+		--sysconfdir=/etc/lftp \
+		--with-modules \
+		${myconf} || die "econf failed"
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+
+	dodoc BUGS ChangeLog FAQ FEATURES MIRRORS \
+			NEWS README* THANKS TODO
+}