Version bumped.

(Portage version: 2.1.7.14/cvs/Linux x86_64)

2 files changed, 67 insertions, 1 deletions

diff --git a/net-dns/unbound/ChangeLog b/net-dns/unbound/ChangeLog
index 6b02dd7a4fa8..04e1e9122b84 100644
--- a/net-dns/unbound/ChangeLog
+++ b/net-dns/unbound/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-dns/unbound
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v 1.2 2009/11/26 15:55:56 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v 1.3 2009/12/17 15:50:33 matsuu Exp $
+
+*unbound-1.4.1 (17 Dec 2009)
+
+  17 Dec 2009; MATSUU Takuto <matsuu@gentoo.org> +unbound-1.4.1.ebuild:
+  Version bumped.
 
 *unbound-1.4.0 (26 Nov 2009)
 
diff --git a/net-dns/unbound/unbound-1.4.1.ebuild b/net-dns/unbound/unbound-1.4.1.ebuild
new file mode 100644
index 000000000000..132ca3f54437
--- /dev/null
+++ b/net-dns/unbound/unbound-1.4.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/unbound-1.4.1.ebuild,v 1.1 2009/12/17 15:50:33 matsuu Exp $
+
+EAPI="2"
+
+inherit autotools eutils multilib
+
+DESCRIPTION="A validating, recursive and caching DNS resolver"
+HOMEPAGE="http://unbound.net/"
+SRC_URI="http://unbound.net/downloads/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug libevent python static test threads"
+
+RDEPEND=">=dev-libs/openssl-0.9.8
+	>=net-libs/ldns-1.4
+	libevent? ( dev-libs/libevent )"
+DEPEND="${RDEPEND}
+	python? ( dev-lang/swig )
+	test? (
+		net-dns/ldns-utils[examples]
+		dev-util/splint
+	)"
+
+pkg_setup() {
+	enewgroup unbound
+	enewuser unbound -1 -1 /etc/unbound unbound
+}
+
+src_prepare() {
+	sed -i -e "s:\(withval\|thedir\)/lib:\1/$(get_libdir):" configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-pidfile=/var/run/unbound.pid \
+		--with-ldns=/usr \
+		$(use_enable debug) \
+		$(use_enable debug lock-checks) \
+		$(use_enable debug alloc-checks) \
+		$(use_enable static static-exe) \
+		$(use_with libevent) \
+		$(use_with threads pthreads) \
+		$(use_with python pyunbound) \
+		$(use_with python pythonmodule) || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	newinitd "${FILESDIR}/unbound.initd" unbound || die "newinitd failed"
+	newconfd "${FILESDIR}/unbound.confd" unbound || die "newconfd failed"
+
+	dodoc doc/{README,CREDITS,TODO,Changelog,FEATURES} || die "dodoc failed"
+
+	exeinto /usr/share/${PN}
+	doexe contrib/{update-anchor,update-itar,split-itar}.sh || die "doexe failed"
+}