Version bump.

(Portage version: 2.2.0_alpha92/cvs/Linux i686)

2 files changed, 94 insertions, 1 deletions

diff --git a/media-sound/tomahawk/ChangeLog b/media-sound/tomahawk/ChangeLog
index cafea65b6405..d708f562fb67 100644
--- a/media-sound/tomahawk/ChangeLog
+++ b/media-sound/tomahawk/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/tomahawk
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/tomahawk/ChangeLog,v 1.6 2012/01/27 19:14:04 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/tomahawk/ChangeLog,v 1.7 2012/03/19 10:15:27 johu Exp $
+
+*tomahawk-0.4.0 (19 Mar 2012)
+
+  19 Mar 2012; Johannes Huber <johu@gentoo.org> +tomahawk-0.4.0.ebuild:
+  Version bump.
 
   27 Jan 2012; Johannes Huber <johu@gentoo.org> metadata.xml:
   Add myself as maintainer.
diff --git a/media-sound/tomahawk/tomahawk-0.4.0.ebuild b/media-sound/tomahawk/tomahawk-0.4.0.ebuild
new file mode 100644
index 000000000000..89e1207d7584
--- /dev/null
+++ b/media-sound/tomahawk/tomahawk-0.4.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/tomahawk/tomahawk-0.4.0.ebuild,v 1.1 2012/03/19 10:15:27 johu Exp $
+
+EAPI=4
+
+QT_MINIMAL="4.7.0"
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="http://download.tomahawk-player.org/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	GIT_ECLASS="git-2"
+	EGIT_REPO_URI="git://github.com/tomahawk-player/tomahawk.git"
+	KEYWORDS=""
+fi
+
+inherit cmake-utils qt4-r2 ${GIT_ECLASS}
+
+DESCRIPTION="Qt playdar social music player"
+HOMEPAGE="http://tomahawk-player.org/"
+
+LICENSE="GPL-3 BSD"
+SLOT="0"
+IUSE="debug fftw jabber libsamplerate +resolver twitter"
+
+DEPEND="
+	app-crypt/qca
+	>=dev-cpp/clucene-2.3.3.4
+	>=dev-libs/boost-1.41
+	>=dev-libs/qjson-0.7.1
+	>=media-libs/libechonest-1.1.10
+	>=media-libs/phonon-4.5.0
+	media-libs/taglib
+	>=x11-libs/qt-core-${QT_MINIMAL}:4
+	>=x11-libs/qt-gui-${QT_MINIMAL}:4
+	>=x11-libs/qt-sql-${QT_MINIMAL}:4[sqlite]
+	>=x11-libs/qt-webkit-${QT_MINIMAL}:4
+	>=x11-libs/qt-xmlpatterns-${QT_MINIMAL}:4
+	fftw? ( sci-libs/fftw:3.0 )
+	jabber? ( net-libs/jreen )
+	libsamplerate? ( media-libs/libsamplerate )
+	resolver? (
+		dev-libs/libattica
+		>=dev-libs/quazip-0.4.3
+	)
+	twitter? ( net-libs/qtweetlib )
+"
+RDEPEND="${DEPEND}
+	app-crypt/qca-ossl
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.3.2-remove-quazip.patch"
+)
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with jabber Jreen)
+		$(cmake-utils_use_with resolver LibAttica)
+		$(cmake-utils_use_with resolver QuaZip)
+		$(cmake-utils_use_with twitter QTweetLib)
+		-DINTERNAL_JREEN=OFF
+	)
+
+	if [[ ${PV} != *9999* ]]; then
+		mycmakeargs+=(	-DBUILD_RELEASE=ON )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+}
+
+pkg_postinst() {
+	if ! use resolver; then
+		echo
+		elog "Information on how to get more resolvers for ${PN}"
+		elog "is available at ${HOMEPAGE}resolvers"
+		echo
+	fi
+}