Fix segfault with recent ffmpeg versions (bug #373423 by Mike MacDonald)

(Portage version: 2.2.0_alpha43/cvs/Linux x86_64)

3 files changed, 210 insertions, 1 deletions

diff --git a/media-sound/mpd/ChangeLog b/media-sound/mpd/ChangeLog
index d2c0f3f9432b..26249b22b53b 100644
--- a/media-sound/mpd/ChangeLog
+++ b/media-sound/mpd/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/mpd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.256 2011/06/25 17:47:22 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.257 2011/07/03 10:30:35 angelos Exp $
+
+*mpd-0.16.3-r1 (03 Jul 2011)
+
+  03 Jul 2011; Christoph Mende <angelos@gentoo.org> +mpd-0.16.3-r1.ebuild,
+  +files/mpd-0.16.3-ffmpeg.patch:
+  Fix segfault with recent ffmpeg versions (bug #373423 by Mike MacDonald)
 
   25 Jun 2011; Christoph Mende <angelos@gentoo.org> mpd-0.15.8.ebuild,
   mpd-0.15.15.ebuild, mpd-0.15.16.ebuild, mpd-0.16.2.ebuild, mpd-0.16.3.ebuild,
diff --git a/media-sound/mpd/files/mpd-0.16.3-ffmpeg.patch b/media-sound/mpd/files/mpd-0.16.3-ffmpeg.patch
new file mode 100644
index 000000000000..a945a0a6ab33
--- /dev/null
+++ b/media-sound/mpd/files/mpd-0.16.3-ffmpeg.patch
@@ -0,0 +1,21 @@
+diff -ur mpd-0.16.3.orig/src/decoder/ffmpeg_decoder_plugin.c mpd-0.16.3/src/decoder/ffmpeg_decoder_plugin.c
+--- mpd-0.16.3.orig/src/decoder/ffmpeg_decoder_plugin.c	2011-06-04 17:36:33.000000000 +0300
++++ mpd-0.16.3/src/decoder/ffmpeg_decoder_plugin.c	2011-06-24 18:18:51.840218251 +0300
+@@ -321,7 +321,7 @@
+ 	}
+ 
+ 	//ffmpeg works with ours "fileops" helper
+-	AVFormatContext *format_context;
++	AVFormatContext *format_context = NULL;
+ 	if (av_open_input_stream(&format_context, stream->io, input->uri,
+ 				 input_format, NULL) != 0) {
+ 		g_warning("Open failed\n");
+@@ -470,7 +470,7 @@
+ 	if (stream == NULL)
+ 		return NULL;
+ 
+-	AVFormatContext *f;
++	AVFormatContext *f = NULL;
+ 	if (av_open_input_stream(&f, stream->io, is->uri,
+ 				 input_format, NULL) != 0) {
+ 		mpd_ffmpeg_stream_close(stream);
diff --git a/media-sound/mpd/mpd-0.16.3-r1.ebuild b/media-sound/mpd/mpd-0.16.3-r1.ebuild
new file mode 100644
index 000000000000..f9b25d2de8fd
--- /dev/null
+++ b/media-sound/mpd/mpd-0.16.3-r1.ebuild
@@ -0,0 +1,182 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.16.3-r1.ebuild,v 1.1 2011/07/03 10:30:35 angelos Exp $
+
+EAPI=4
+inherit eutils flag-o-matic linux-info multilib
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="http://www.musicpd.org"
+SRC_URI="mirror://sourceforge/musicpd/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="aac +alsa ao audiofile bzip2 cdio cue +curl debug +fifo +ffmpeg flac
+fluidsynth profile +id3tag inotify ipv6 jack lame lastfmradio libmms libsamplerate
++mad mikmod modplug mpg123 musepack +network ogg openal oss pipe pulseaudio sid
+sndfile sqlite tcpd twolame unicode vorbis wavpack wildmidi zeroconf zip"
+
+REQUIRED_USE="|| ( alsa ao fifo jack network openal oss pipe pulseaudio )
+	|| ( aac audiofile ffmpeg flac fluidsynth mad mikmod modplug mpg123 musepack
+			ogg flac sid vorbis wavpack wildmidi )
+	network? ( || ( audiofile flac lame twolame vorbis ) )
+	lastfmradio? ( curl )"
+
+RDEPEND="!<sys-cluster/mpich2-1.4_rc2
+	dev-libs/glib:2
+	aac? ( media-libs/faad2 )
+	alsa? ( media-sound/alsa-utils )
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio )
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	ffmpeg? ( virtual/ffmpeg )
+	flac? ( media-libs/flac[ogg?] )
+	fluidsynth? ( media-sound/fluidsynth )
+	network? ( >=media-libs/libshout-2
+		!lame? ( !vorbis? ( media-libs/libvorbis ) ) )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( media-sound/jack-audio-connection-kit )
+	lame? ( network? ( media-sound/lame ) )
+	libmms? ( media-libs/libmms )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( >=media-sound/mpg123-1.12.2 )
+	musepack? ( media-sound/musepack-tools )
+	ogg? ( media-libs/libogg )
+	openal? ( media-libs/openal )
+	pulseaudio? ( media-sound/pulseaudio )
+	sid? ( media-libs/libsidplay:2 )
+	sndfile? ( media-libs/libsndfile )
+	sqlite? ( dev-db/sqlite:3 )
+	tcpd? ( sys-apps/tcp-wrappers )
+	twolame? ( media-sound/twolame )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	use network || ewarn "Icecast and Shoutcast streaming needs networking."
+	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
+
+	enewuser mpd "" "" "/var/lib/mpd" audio
+
+	if use inotify; then
+		CONFIG_CHECK="~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
+	epatch "${FILESDIR}"/${PN}-0.16.conf.patch \
+		"${FILESDIR}"/${P}-ffmpeg.patch
+}
+
+src_configure() {
+	local mpdconf="--enable-tcp --enable-un	--disable-documentation
+		--disable-ffado --disable-gme --enable-largefile
+		--disable-mvp --docdir=${EPREFIX}/usr/share/doc/${PF}"
+
+	if use network; then
+		mpdconf+=" --enable-shout $(use_enable vorbis vorbis-encoder)
+			--enable-httpd-output $(use_enable lame lame-encoder)
+			$(use_enable twolame twolame-encoder)
+			$(use_enable audiofile wave-encoder)"
+	else
+		mpdconf+=" --disable-shout --disable-vorbis-encoder
+			--disable-httpd-output --disable-lame-encoder
+			--disable-twolame-encoder --disable-wave-encoder"
+	fi
+
+	if use flac && use ogg; then
+		mpdconf+=" --enable-oggflac"
+	else
+		mpdconf+=" --disable-oggflac"
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+	econf \
+		$(use_enable aac) \
+		$(use_enable alsa) \
+		$(use_enable ao) \
+		$(use_enable audiofile) \
+		$(use_enable bzip2) \
+		$(use_enable cdio iso9660) \
+		$(use_enable cue) \
+		$(use_enable curl) \
+		$(use_enable debug) \
+		$(use_enable ffmpeg) \
+		$(use_enable fifo) \
+		$(use_enable flac) \
+		$(use_enable fluidsynth) \
+		$(use_enable id3tag id3) \
+		$(use_enable inotify) \
+		$(use_enable ipv6) \
+		$(use_enable jack) \
+		$(use_enable lastfmradio lastfm) \
+		$(use_enable libmms mms) \
+		$(use_enable libsamplerate lsr) \
+		$(use_enable mad) \
+		$(use_enable mikmod) \
+		$(use_enable modplug) \
+		$(use_enable mpg123) \
+		$(use_enable musepack mpc) \
+		$(use_enable openal) \
+		$(use_enable oss) \
+		$(use_enable pipe pipe-output) \
+		$(use_enable profile gprof) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable sid sidplay) \
+		$(use_enable sndfile sndfile) \
+		$(use_enable sqlite) \
+		$(use_enable tcpd libwrap) \
+		$(use_enable vorbis) \
+		$(use_enable wavpack) \
+		$(use_enable wildmidi) \
+		$(use_enable zip zzip) \
+		$(use_with zeroconf zeroconf avahi) \
+		${mpdconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	insinto /etc
+	newins doc/mpdconf.dist mpd.conf
+
+	newinitd "${FILESDIR}"/mpd.init mpd
+
+	if use unicode; then
+		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+			"${D}"/etc/mpd.conf || die "sed failed"
+	fi
+
+	diropts -m0755 -o mpd -g audio
+	dodir /var/lib/mpd
+	keepdir /var/lib/mpd
+	dodir /var/lib/mpd/music
+	keepdir /var/lib/mpd/music
+	dodir /var/lib/mpd/playlists
+	keepdir /var/lib/mpd/playlists
+}
+
+pkg_postinst() {
+	elog "If you will be starting mpd via /etc/init.d/mpd, please make"
+	elog "sure that MPD's pid_file is unset."
+
+	# also change the homedir if the user has existed before
+	usermod -d "/var/lib/mpd" mpd
+}