Version bump. Add lv2 use flag and update to EAPI 4.

(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

3 files changed, 114 insertions, 7 deletions

diff --git a/media-sound/ecasound/ChangeLog b/media-sound/ecasound/ChangeLog
index 0317c191d2e3..8cd8f296fb97 100644
--- a/media-sound/ecasound/ChangeLog
+++ b/media-sound/ecasound/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/ecasound
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/ecasound/ChangeLog,v 1.63 2012/06/14 05:55:53 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/ecasound/ChangeLog,v 1.64 2012/06/14 06:22:46 radhermit Exp $
+
+*ecasound-2.9.0 (14 Jun 2012)
+
+  14 Jun 2012; Tim Harder <radhermit@gentoo.org> +ecasound-2.9.0.ebuild,
+  metadata.xml:
+  Version bump. Add lv2 use flag and update to EAPI 4.
 
   14 Jun 2012; Tim Harder <radhermit@gentoo.org> ecasound-2.8.1.ebuild:
   Fix conditional sed line (bug #387819) and use prune_libtool_files.
diff --git a/media-sound/ecasound/ecasound-2.9.0.ebuild b/media-sound/ecasound/ecasound-2.9.0.ebuild
new file mode 100644
index 000000000000..7a07eec141ae
--- /dev/null
+++ b/media-sound/ecasound/ecasound-2.9.0.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/ecasound/ecasound-2.9.0.ebuild,v 1.1 2012/06/14 06:22:46 radhermit Exp $
+
+EAPI=4
+PYTHON_DEPEND="python? 2"
+
+inherit eutils python autotools
+
+DESCRIPTION="a package for multitrack audio processing"
+HOMEPAGE="http://ecasound.seul.org/ecasound"
+SRC_URI="http://ecasound.seul.org/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="1"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa audiofile debug doc jack libsamplerate lv2 mikmod ncurses oil osc oss
+python ruby sndfile static-libs"
+
+RDEPEND="sys-libs/readline
+	alsa? ( media-libs/alsa-lib )
+	audiofile? ( media-libs/audiofile )
+	jack? ( media-sound/jack-audio-connection-kit )
+	libsamplerate? ( media-libs/libsamplerate )
+	lv2? ( >=media-libs/lilv-0.5.0 )
+	media-libs/ladspa-sdk
+	mikmod? ( media-libs/libmikmod:0 )
+	ncurses? ( sys-libs/ncurses )
+	oil? ( dev-libs/liboil )
+	osc? ( media-libs/liblo )
+	ruby? ( dev-lang/ruby )
+	sndfile? ( media-libs/libsndfile )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+pkg_setup() {
+	use python && python_set_active_version 2
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.8.1-ldflags.patch
+
+	if use python ; then
+		sed -i -e "s:\$(ecasoundc_libs):\0 $(python_get_library -l):" \
+			pyecasound/Makefile.am || die "sed failed"
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	local pyconf
+
+	if use python ; then
+		pyconf="--enable-pyecasound=c
+			--with-python-includes=$(python_get_includedir)
+			--with-python-modules=$(python_get_libdir)"
+	else
+		pyconf="--disable-pyecasound"
+	fi
+
+	econf \
+		--disable-arts \
+		--enable-shared \
+		--enable-sys-readline \
+		--with-largefile \
+		$(use_enable alsa) \
+		$(use_enable audiofile) \
+		$(use_enable debug) \
+		$(use_enable jack) \
+		$(use_enable libsamplerate) \
+		$(use_enable lv2 liblilv) \
+		$(use_enable ncurses) \
+		$(use_enable oil liboil) \
+		$(use_enable osc liblo) \
+		$(use_enable oss) \
+		$(use_enable ruby rubyecasound) \
+		$(use_enable sndfile) \
+		$(use_enable static-libs static) \
+		${pyconf}
+}
+
+src_install() {
+	default
+
+	if use doc ; then
+		dohtml Documentation/*.html
+		dodoc Documentation/programmers_guide/ecasound_programmers_guide.txt
+	fi
+
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	use python && python_mod_optimize ecacontrol.py eci.py pyeca.py
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup ecacontrol.py eci.py pyeca.py
+}
diff --git a/media-sound/ecasound/metadata.xml b/media-sound/ecasound/metadata.xml
index 44fa6c3beecb..c48ef0397652 100644
--- a/media-sound/ecasound/metadata.xml
+++ b/media-sound/ecasound/metadata.xml
@@ -3,17 +3,18 @@
 <pkgmetadata>
 <herd>proaudio</herd>
 <longdescription>
-	Ecasound is a software package designed for multitrack audio 
+	Ecasound is a software package designed for multitrack audio
 	processing. It can be used for simple tasks like audio playback,
-	recording and format conversions, as well as for multitrack 
-	effect processing, mixing, recording and signal recycling. 
-	Ecasound supports a wide range of audio inputs, outputs and 
-	effect algorithms. Effects and audio objects can be combined 
+	recording and format conversions, as well as for multitrack
+	effect processing, mixing, recording and signal recycling.
+	Ecasound supports a wide range of audio inputs, outputs and
+	effect algorithms. Effects and audio objects can be combined
 	in various ways, and their parameters can be controlled by operator
-	objects like oscillators and MIDI-CCs. A versatile console mode 
+	objects like oscillators and MIDI-CCs. A versatile console mode
 	user-interface is included in the package.
 </longdescription>
 <use>
 	<flag name="oil">Use <pkg>dev-libs/liboil</pkg> for inner loop optimizations</flag>
+	<flag name="lv2">Add support for Ladspa V2</flag>
 </use>
 </pkgmetadata>