Version bump.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

3 files changed, 86 insertions, 1 deletions

diff --git a/media-sound/easytag/ChangeLog b/media-sound/easytag/ChangeLog
index 374c9245bbb5..e7e7ea4444c5 100644
--- a/media-sound/easytag/ChangeLog
+++ b/media-sound/easytag/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/easytag
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/easytag/ChangeLog,v 1.181 2014/03/21 17:00:29 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/easytag/ChangeLog,v 1.182 2014/04/13 07:49:25 ssuominen Exp $
+
+*easytag-2.2.0 (13 Apr 2014)
+
+  13 Apr 2014; Samuli Suominen <ssuominen@gentoo.org> +easytag-2.2.0.ebuild,
+  metadata.xml:
+  Version bump.
 
   21 Mar 2014; Jeroen Roovers <jer@gentoo.org> easytag-2.1.10-r1.ebuild:
   Marked ~hppa (bug #503608).
diff --git a/media-sound/easytag/easytag-2.2.0.ebuild b/media-sound/easytag/easytag-2.2.0.ebuild
new file mode 100644
index 000000000000..69f978db19bb
--- /dev/null
+++ b/media-sound/easytag/easytag-2.2.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/easytag/easytag-2.2.0.ebuild,v 1.1 2014/04/13 07:49:25 ssuominen Exp $
+
+EAPI=5
+inherit gnome.org gnome2-utils fdo-mime
+
+DESCRIPTION="GTK+ utility for editing MP2, MP3, MP4, FLAC, Ogg and other media tags"
+HOMEPAGE="https://wiki.gnome.org/Apps/EasyTAG"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flac mp3 nls opus speex test wavpack"
+
+RDEPEND=">=dev-libs/glib-2
+	media-libs/libogg
+	media-libs/libvorbis
+	media-libs/taglib[mp4]
+	>=x11-libs/gtk+-3.4:3
+	flac? ( media-libs/flac )
+	mp3? (
+		>=media-libs/id3lib-3.8.3-r8
+		>=media-libs/libid3tag-0.15.1b-r4
+		)
+	opus? (
+		media-libs/opus
+		media-libs/opusfile
+		)
+	speex? ( media-libs/speex )
+	wavpack? ( media-sound/wavpack )"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.4
+	app-text/yelp-tools
+	dev-libs/libxml2
+	dev-libs/libxslt
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? (
+		dev-util/appdata-tools
+		dev-util/desktop-file-utils
+		)"
+
+src_prepare() {
+	sed -i \
+		-e '/^DEPRECATED_CPPFLAGS="/d' \
+		-e '/warning_flags/s: -Werror=.*:":' \
+		configure || die
+}
+
+DOCS=( AUTHORS ChangeLog HACKING NEWS README THANKS TODO )
+
+src_configure() {
+	# Kludge to make easytag find its locales (bug #503698)
+	export DATADIRNAME=share
+
+	# FIXME: src/gio_wrapper.h -> taglib #include without #ifdef -> --enable-mp4
+	# FIXME: src/vcedit.h -> ogg and vorbis #include without #ifdef -> --enable-ogg
+	econf \
+		$(use_enable nls) \
+		$(use_enable test appdata-validate) \
+		$(use_enable test tests) \
+		$(use_enable mp3) \
+		$(use_enable mp3 id3v23) \
+		--enable-ogg \
+		$(use_enable opus) \
+		$(use_enable speex) \
+		$(use_enable flac) \
+		--enable-mp4 \
+		$(use_enable wavpack)
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; fdo-mime_desktop_database_update; }
+pkg_postrm() { gnome2_icon_cache_update; fdo-mime_desktop_database_update; }
diff --git a/media-sound/easytag/metadata.xml b/media-sound/easytag/metadata.xml
index ea604b720fd0..a9fff8a9fd87 100644
--- a/media-sound/easytag/metadata.xml
+++ b/media-sound/easytag/metadata.xml
@@ -2,5 +2,8 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
   <herd>sound</herd>
+  <use>
+    <flag name='opus'>Enable support for <pkg>media-libs/opus</pkg> and <pkg>media-libs/opusfile</pkg> (opus audio codec)</flag>
+  </use>
   <longdescription>a utility for viewing and editing tags for MP3, MP2, FLAC, AAC, MP4 and OGG files. It features a simple and attractive GTK+ interface</longdescription>
 </pkgmetadata>