version bump

(Portage version: 2.2.0_alpha162/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

3 files changed, 110 insertions, 2 deletions

diff --git a/media-sound/audacity/ChangeLog b/media-sound/audacity/ChangeLog
index 9b877484c667..fba1519f04a2 100644
--- a/media-sound/audacity/ChangeLog
+++ b/media-sound/audacity/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/audacity
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/audacity/ChangeLog,v 1.179 2012/10/11 23:26:38 blueness Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacity/ChangeLog,v 1.180 2013/02/13 18:23:40 aballier Exp $
+
+*audacity-2.0.3 (13 Feb 2013)
+
+  13 Feb 2013; Alexis Ballier <aballier@gentoo.org> +audacity-2.0.3.ebuild:
+  version bump
 
   11 Oct 2012; Anthony G. Basile <blueness@gentoo.org> audacity-2.0.1.ebuild,
   audacity-2.0.2.ebuild:
diff --git a/media-sound/audacity/audacity-2.0.3.ebuild b/media-sound/audacity/audacity-2.0.3.ebuild
new file mode 100644
index 000000000000..426c9fc3033e
--- /dev/null
+++ b/media-sound/audacity/audacity-2.0.3.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacity/audacity-2.0.3.ebuild,v 1.1 2013/02/13 18:23:40 aballier Exp $
+
+EAPI=4
+
+inherit eutils wxwidgets autotools versionator
+
+MY_PV=$(replace_version_separator 3 -)
+MY_P="${PN}-src-${MY_PV}"
+MY_T="${PN}-minsrc-${MY_PV}"
+DESCRIPTION="Free crossplatform audio editor"
+HOMEPAGE="http://audacity.sourceforge.net/"
+SRC_URI="http://audacity.googlecode.com/files/${MY_T}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~mips"
+IUSE="alsa ffmpeg flac id3tag jack ladspa libsamplerate +libsoxr midi mp3 sbsms soundtouch twolame vamp vorbis"
+RESTRICT="test"
+
+COMMON_DEPEND="x11-libs/wxGTK:2.8[X]
+	>=app-arch/zip-2.3
+	>=media-libs/libsndfile-1.0.0
+	dev-libs/expat
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )
+	libsoxr? ( media-libs/soxr )
+	vorbis? ( >=media-libs/libvorbis-1.0 )
+	mp3? ( >=media-libs/libmad-0.14.2b )
+	flac? ( >=media-libs/flac-1.2.0[cxx] )
+	id3tag? ( media-libs/libid3tag )
+	sbsms? ( media-libs/libsbsms )
+	soundtouch? ( >=media-libs/libsoundtouch-1.3.1 )
+	vamp? ( >=media-libs/vamp-plugin-sdk-2.0 )
+	twolame? ( media-sound/twolame )
+	ffmpeg? ( virtual/ffmpeg )
+	alsa? ( media-libs/alsa-lib )
+	jack? ( >=media-sound/jack-audio-connection-kit-0.103.0 )"
+# Crashes at  startup here...
+#	lv2? ( >=media-libs/slv2-0.6.0 )
+# Disabled upstream ATM
+#  ladspa? ( >=media-libs/liblrdf-0.4.0 )
+
+RDEPEND="${COMMON_DEPEND}
+	mp3? ( >=media-sound/lame-3.70 )"
+DEPEND="${COMMON_DEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+
+REQUIRED_USE="soundtouch? ( midi )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.3.13-automagic.patch
+
+	AT_M4DIR="${S}/m4" eautoreconf
+}
+
+src_configure() {
+	WX_GTK_VER="2.8"
+	need-wxwidgets unicode
+
+	# * always use system libraries if possible
+	# * options listed in the order that configure --help lists them
+	# * if libsamplerate not requested, use libresample instead.
+	econf \
+		--enable-unicode \
+		--enable-nyquist \
+		--disable-dynamic-loading \
+		$(use_enable ladspa) \
+		--with-libsndfile=system \
+		--with-expat=system \
+		$(use_with libsamplerate) \
+		$(use_with !libsamplerate libresample) \
+		$(use_with libsoxr) \
+		$(use_with vorbis libvorbis) \
+		$(use_with mp3 libmad) \
+		$(use_with flac libflac) \
+		$(use_with id3tag libid3tag) \
+		$(use_with sbsms) \
+		$(use_with soundtouch) \
+		$(use_with vamp libvamp) \
+		$(use_with twolame libtwolame) \
+		$(use_with ffmpeg) \
+		$(use_with midi) \
+		$(use_with alsa) \
+		$(use_with jack)
+}
+
+# $(use_with lv2 slv2) \
+# $(use_with ladspa liblrdf) \
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	# Remove bad doc install
+	rm -rf "${D}"/usr/share/doc
+
+	# Install our docs
+	dodoc README.txt
+}
diff --git a/media-sound/audacity/metadata.xml b/media-sound/audacity/metadata.xml
index 37d4cc857b6a..571c5a2b3cd9 100644
--- a/media-sound/audacity/metadata.xml
+++ b/media-sound/audacity/metadata.xml
@@ -9,6 +9,7 @@
 	</maintainer>
 	<use>
 		<flag name="id3tag">Enables ID3 tagging with id3tag library</flag>
+		<flag name="libsoxr">Uses <pkg>media-libs/soxr</pkg> as audio resampling library: Better quality than the included resampler and much faster than libsamplerate while keeping almost the same quality.</flag>
 		<flag name="midi">Enables MIDI support</flag>
 		<flag name="sbsms">Enables sbsms library support for pitch and tempo changing</flag>
 		<flag name="soundtouch">Enables soundtouch library support for pitch and tempo changing</flag>