Version bump.

(Portage version: 2.1.2_pre2)

3 files changed, 80 insertions, 1 deletions

diff --git a/media-plugins/alsa-plugins/ChangeLog b/media-plugins/alsa-plugins/ChangeLog
index aa5157718d85..1a5cad9b26a0 100644
--- a/media-plugins/alsa-plugins/ChangeLog
+++ b/media-plugins/alsa-plugins/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/alsa-plugins
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v 1.14 2006/09/24 17:32:12 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v 1.15 2006/09/30 13:42:50 flameeyes Exp $
+
+*alsa-plugins-1.0.13 (30 Sep 2006)
+
+  30 Sep 2006; Diego Pettenò <flameeyes@gentoo.org>
+  +alsa-plugins-1.0.13.ebuild:
+  Version bump.
 
   24 Sep 2006; Diego Pettenò <flameeyes@gentoo.org>
   alsa-plugins-1.0.11.ebuild, alsa-plugins-1.0.12.ebuild,
diff --git a/media-plugins/alsa-plugins/alsa-plugins-1.0.13.ebuild b/media-plugins/alsa-plugins/alsa-plugins-1.0.13.ebuild
new file mode 100644
index 000000000000..c7cf9ea82bd6
--- /dev/null
+++ b/media-plugins/alsa-plugins/alsa-plugins-1.0.13.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/alsa-plugins-1.0.13.ebuild,v 1.1 2006/09/30 13:42:50 flameeyes Exp $
+
+WANT_AUTOMAKE=latest
+WANT_AUTOCONF=latest
+
+inherit libtool autotools eutils flag-o-matic
+
+MY_P="${P/_/}"
+
+DESCRIPTION="ALSA extra plugins"
+HOMEPAGE="http://www.alsa-project.org/"
+SRC_URI="mirror://alsaproject/plugins/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="jack ffmpeg libsamplerate pulseaudio debug"
+
+RDEPEND=">=media-libs/alsa-lib-1.0.12_rc1
+	jack? ( >=media-sound/jack-audio-connection-kit-0.98 )
+	ffmpeg? ( media-video/ffmpeg )
+	libsamplerate? ( media-libs/libsamplerate )
+	pulseaudio? ( media-sound/pulseaudio )
+	!media-plugins/alsa-jack"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${PN}-1.0.12-automagic.patch"
+
+	# For some reasons the polyp/pulse plugin does fail with alsaplayer with a
+	# failed assert. As the code works just fine with asserts disabled, for now
+	# disable them waiting for a better solution.
+	sed -i -e '/AM_CFLAGS/s:-Wall:-DNDEBUG -Wall:' \
+		"${S}/pulse/Makefile.am"
+
+	eautoreconf
+
+	elibtoolize
+}
+
+src_compile() {
+	use debug || append-flags -DNDEBUG
+	econf \
+		$(use_enable jack) \
+		$(use_enable libsamplerate samplerate) \
+		$(use_enable ffmpeg avcodec) \
+		$(use_enable pulseaudio) \
+		--disable-dependency-tracking \
+		|| die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	cd "${S}/doc"
+	dodoc upmix.txt vdownmix.txt README-pcm-oss
+	use jack && dodoc README-jack
+	use libsamplerate && dodoc samplerate.txt
+	use pulseaudio && dodoc README-pulse
+}
diff --git a/media-plugins/alsa-plugins/files/digest-alsa-plugins-1.0.13 b/media-plugins/alsa-plugins/files/digest-alsa-plugins-1.0.13
new file mode 100644
index 000000000000..d92b767b553c
--- /dev/null
+++ b/media-plugins/alsa-plugins/files/digest-alsa-plugins-1.0.13
@@ -0,0 +1,3 @@
+MD5 7ef5e429b4a2756d0b5f0d7ce5bba0c8 alsa-plugins-1.0.13.tar.bz2 230257
+RMD160 c13fef547fc29bb2f7fd60e3a962e4c299cf677a alsa-plugins-1.0.13.tar.bz2 230257
+SHA256 9a1a68f13e00400a2f8b7fe77c33d715b4a048931908d7c8c082adaf55c207a0 alsa-plugins-1.0.13.tar.bz2 230257