Backport the speex changes from #193768 to 1.0.14.

(Portage version: 2.1.3.9)

3 files changed, 89 insertions, 1 deletions

diff --git a/media-plugins/alsa-plugins/ChangeLog b/media-plugins/alsa-plugins/ChangeLog
index f38c67a93361..b85a4e96c377 100644
--- a/media-plugins/alsa-plugins/ChangeLog
+++ b/media-plugins/alsa-plugins/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/alsa-plugins
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v 1.62 2007/10/20 15:39:25 phreak Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v 1.63 2007/10/20 15:46:55 phreak Exp $
+
+*alsa-plugins-1.0.14-r1 (20 Oct 2007)
+
+  20 Oct 2007; Christian Heim <phreak@gentoo.org>
+  +alsa-plugins-1.0.14-r1.ebuild:
+  Backport the speex changes from #193768 to 1.0.14.
 
   20 Oct 2007; Christian Heim <phreak@gentoo.org>
   alsa-plugins-1.0.15.ebuild:
diff --git a/media-plugins/alsa-plugins/alsa-plugins-1.0.14-r1.ebuild b/media-plugins/alsa-plugins/alsa-plugins-1.0.14-r1.ebuild
new file mode 100644
index 000000000000..ac1bf7a2d3ec
--- /dev/null
+++ b/media-plugins/alsa-plugins/alsa-plugins-1.0.14-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/alsa-plugins-1.0.14-r1.ebuild,v 1.1 2007/10/20 15:46:55 phreak Exp $
+
+WANT_AUTOMAKE=latest
+WANT_AUTOCONF=latest
+
+inherit libtool autotools eutils flag-o-matic
+
+MY_P="${P/_/}"
+
+DESCRIPTION="ALSA extra plugins"
+HOMEPAGE="http://www.alsa-project.org/"
+SRC_URI="mirror://alsaproject/plugins/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
+IUSE="debug ffmpeg jack libsamplerate pulseaudio speex"
+
+RDEPEND=">=media-libs/alsa-lib-${PV}
+	ffmpeg? ( media-video/ffmpeg )
+	jack? ( >=media-sound/jack-audio-connection-kit-0.98 )
+	libsamplerate? ( media-libs/libsamplerate )
+	pulseaudio? ( media-sound/pulseaudio )
+	speex? ( media-libs/speex )
+	!media-plugins/alsa-jack"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${PN}-1.0.14_rc1-automagic.patch"
+	epatch "${FILESDIR}/${PN}-1.0.14_rc1-init-ffmpeg.patch"
+
+	# For some reasons the polyp/pulse plugin does fail with alsaplayer with a
+	# failed assert. As the code works just fine with asserts disabled, for now
+	# disable them waiting for a better solution.
+	sed -i -e '/AM_CFLAGS/s:-Wall:-DNDEBUG -Wall:' \
+		"${S}/pulse/Makefile.am"
+
+	eautoreconf
+	elibtoolize
+}
+
+src_compile() {
+	use debug || append-flags -DNDEBUG
+
+	# D-Bus is used for Maemo SDK, that standing to the
+	# changelog is related to n770... disable it until
+	# someone ask for it explicitely, to be on the safe
+	# side.
+	econf \
+		$(use_enable ffmpeg avcodec) \
+		$(use_enable jack) \
+		$(use_enable libsamplerate samplerate) \
+		$(use_enable pulseaudio) \
+		$(use_with speex speex lib) \
+		--disable-dbus \
+		--disable-dependency-tracking \
+		|| die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	cd "${S}/doc"
+	dodoc upmix.txt vdownmix.txt README-pcm-oss
+	use jack && dodoc README-jack
+	use libsamplerate && dodoc samplerate.txt
+	use pulseaudio && dodoc README-pulse
+	use ffmpeg && dodoc lavcrate.txt a52.txt
+}
diff --git a/media-plugins/alsa-plugins/files/digest-alsa-plugins-1.0.14-r1 b/media-plugins/alsa-plugins/files/digest-alsa-plugins-1.0.14-r1
new file mode 100644
index 000000000000..d803432e45c8
--- /dev/null
+++ b/media-plugins/alsa-plugins/files/digest-alsa-plugins-1.0.14-r1
@@ -0,0 +1,3 @@
+MD5 fa678da6b91c9f3c7204bc8d14e5b53f alsa-plugins-1.0.14.tar.bz2 305631
+RMD160 3e13375caf25909a08d8683ebff1025743c0ee03 alsa-plugins-1.0.14.tar.bz2 305631
+SHA256 c897b1bdec8a392ce4420e5f35d9e559787011c84f2214a27dae43b74dad1638 alsa-plugins-1.0.14.tar.bz2 305631