Version bump wrt #522618 (raise subslot based on SONAME)

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

3 files changed, 81 insertions, 3 deletions

diff --git a/media-libs/x265/ChangeLog b/media-libs/x265/ChangeLog
index 19dc45bac00f..1ece2fa9c9ed 100644
--- a/media-libs/x265/ChangeLog
+++ b/media-libs/x265/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/x265
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/x265/ChangeLog,v 1.11 2014/07/28 08:03:05 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/x265/ChangeLog,v 1.12 2014/09/12 07:05:00 ssuominen Exp $
+
+*x265-1.3 (12 Sep 2014)
+
+  12 Sep 2014; Samuli Suominen <ssuominen@gentoo.org> +x265-1.3.ebuild,
+  x265-9999.ebuild:
+  Version bump wrt #522618 (raise subslot based on SONAME)
 
   28 Jul 2014; Samuli Suominen <ssuominen@gentoo.org> x265-9999.ebuild:
   Add ~arm to KEYWORDS also in -9999.ebuild because it's the base for next
diff --git a/media-libs/x265/x265-1.3.ebuild b/media-libs/x265/x265-1.3.ebuild
new file mode 100644
index 000000000000..20ae72269caf
--- /dev/null
+++ b/media-libs/x265/x265-1.3.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/x265/x265-1.3.ebuild,v 1.1 2014/09/12 07:05:00 ssuominen Exp $
+
+EAPI=5
+
+inherit cmake-multilib multilib flag-o-matic
+
+if [[ ${PV} = 9999* ]]; then
+	inherit mercurial
+	EHG_REPO_URI="http://bitbucket.org/multicoreware/x265"
+else
+	SRC_URI="https://bitbucket.org/multicoreware/x265/get/${PV}.tar.bz2 -> ${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+DESCRIPTION="Library for encoding video streams into the H.265/HEVC format"
+HOMEPAGE="http://x265.org/"
+
+LICENSE="GPL-2"
+# subslot = libx265 soname
+SLOT="0/31"
+IUSE="+10bit test"
+
+ASM_DEPEND=">=dev-lang/yasm-1.2.0"
+RDEPEND=""
+DEPEND="${RDEPEND}
+	abi_x86_32? ( ${ASM_DEPEND} )
+	abi_x86_64? ( ${ASM_DEPEND} )"
+
+src_unpack() {
+	if [[ ${PV} = 9999* ]]; then
+		mercurial_src_unpack
+		# Can't set it at global scope due to mercurial.eclass limitations...
+		export S=${WORKDIR}/${P}/source
+	else
+		unpack ${A}
+		export S=$(echo "${WORKDIR}"/*${PN}*/source)
+	fi
+}
+
+multilib_src_configure() {
+	append-cflags -fPIC
+	append-cxxflags -fPIC
+	local mycmakeargs=(
+		$(cmake-utils_use_enable test TESTS)
+		$(multilib_is_native_abi || echo "-DENABLE_CLI=OFF")
+		-DHIGH_BIT_DEPTH=$(usex 10bit "ON" "OFF")
+		-DLIB_INSTALL_DIR="$(get_libdir)"
+	)
+	cmake-utils_src_configure
+}
+
+src_configure() {
+	multilib_parallel_foreach_abi multilib_src_configure
+}
+
+multilib_src_test() {
+	cd "${BUILD_DIR}/test" || die
+	for i in PoolTest TestBench ; do
+		./${i} || die
+	done
+}
+
+src_test() {
+	multilib_foreach_abi multilib_src_test
+}
+
+src_install() {
+	cmake-multilib_src_install
+	dodoc -r "${S}/../doc/"*
+}
diff --git a/media-libs/x265/x265-9999.ebuild b/media-libs/x265/x265-9999.ebuild
index 81cdac13705e..1fcc11f1bfff 100644
--- a/media-libs/x265/x265-9999.ebuild
+++ b/media-libs/x265/x265-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/x265/x265-9999.ebuild,v 1.9 2014/07/28 08:03:05 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/x265/x265-9999.ebuild,v 1.10 2014/09/12 07:05:00 ssuominen Exp $
 
 EAPI=5
 
@@ -19,7 +19,7 @@ HOMEPAGE="http://x265.org/"
 
 LICENSE="GPL-2"
 # subslot = libx265 soname
-SLOT="0/25"
+SLOT="0/31"
 IUSE="+10bit test"
 
 ASM_DEPEND=">=dev-lang/yasm-1.2.0"