Version bump wrt #513528 by "RAPHEAD". Don't pass --with-xml2-config=no or --with-curl-config=no because upstream changed configure.ac and they break the configure now.

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 74 insertions, 1 deletions

diff --git a/media-libs/raptor/ChangeLog b/media-libs/raptor/ChangeLog
index 86d686590ea3..16aa85e51ba7 100644
--- a/media-libs/raptor/ChangeLog
+++ b/media-libs/raptor/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/raptor
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/ChangeLog,v 1.157 2014/03/04 22:30:42 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/ChangeLog,v 1.158 2014/10/21 04:22:41 ssuominen Exp $
+
+*raptor-2.0.14 (21 Oct 2014)
+
+  21 Oct 2014; Samuli Suominen <ssuominen@gentoo.org> +raptor-2.0.14.ebuild:
+  Version bump wrt #513528 by "RAPHEAD". Don't pass --with-xml2-config=no or
+  --with-curl-config=no because upstream changed configure.ac and they break the
+  configure now.
 
   04 Mar 2014; Andreas K. Huettel <dilfridge@gentoo.org> -raptor-2.0.8.ebuild:
   Remove old so we can close bug 468042
diff --git a/media-libs/raptor/raptor-2.0.14.ebuild b/media-libs/raptor/raptor-2.0.14.ebuild
new file mode 100644
index 000000000000..fb542e852114
--- /dev/null
+++ b/media-libs/raptor/raptor-2.0.14.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/raptor-2.0.14.ebuild,v 1.1 2014/10/21 04:22:41 ssuominen Exp $
+
+EAPI=5
+inherit eutils libtool
+
+MY_PN=${PN}2
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="The RDF Parser Toolkit"
+HOMEPAGE="http://librdf.org/raptor/"
+SRC_URI="http://download.librdf.org/source/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+curl debug json static-libs unicode"
+
+RDEPEND="dev-libs/libxml2
+	dev-libs/libxslt
+	curl? ( net-misc/curl )
+	json? ( dev-libs/yajl )
+	unicode? ( dev-libs/icu:= )
+	!media-libs/raptor:0"
+DEPEND="${RDEPEND}
+	>=sys-devel/bison-3
+	sys-devel/flex
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS="AUTHORS ChangeLog NEWS NOTICE README"
+
+src_prepare() {
+	elibtoolize # Keep this for ~*-fbsd
+}
+
+src_configure() {
+	# FIXME: It should be possible to use net-nntp/inn for libinn.h and -linn!
+
+	local myconf='--with-www=xml'
+	use curl && myconf='--with-www=curl'
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable debug) \
+		$(use unicode && echo --with-icu-config="${EPREFIX}"/usr/bin/icu-config) \
+		$(use_with json yajl) \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		${myconf}
+}
+
+src_test() {
+	emake -j1 test
+}
+
+src_install() {
+	default
+	dohtml {NEWS,README,RELEASE,UPGRADING}.html
+	prune_libtool_files --all
+
+	# http://bugs.gentoo.org/467768
+	local _rdocdir=/usr/share/doc/${PF}/html/${MY_PN}
+	[[ -d ${_rdocdir} ]] && dosym ${_rdocdir} /usr/share/gtk-doc/html/${MY_PN}
+}