Version bump wrt #264954, thanks to Wicher Minnaard for reporting.

(Portage version: 2.1.6.13/cvs/Linux x86_64)

2 files changed, 63 insertions, 1 deletions

diff --git a/media-libs/libtheora/ChangeLog b/media-libs/libtheora/ChangeLog
index 123f1816ef59..91752300883f 100644
--- a/media-libs/libtheora/ChangeLog
+++ b/media-libs/libtheora/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libtheora
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libtheora/ChangeLog,v 1.87 2009/05/05 07:29:12 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libtheora/ChangeLog,v 1.88 2009/05/07 08:38:39 ssuominen Exp $
+
+*libtheora-1.1_alpha1 (07 May 2009)
+
+  07 May 2009; Samuli Suominen <ssuominen@gentoo.org>
+  +libtheora-1.1_alpha1.ebuild:
+  Version bump wrt #264954, thanks to Wicher Minnaard for reporting.
 
   05 May 2009; Samuli Suominen <ssuominen@gentoo.org> libtheora-1.0.ebuild:
   Add VARTEXFONTS variable to avoid sandbox failure wrt #218145, Comment #6.
diff --git a/media-libs/libtheora/libtheora-1.1_alpha1.ebuild b/media-libs/libtheora/libtheora-1.1_alpha1.ebuild
new file mode 100644
index 000000000000..48532cdcfe99
--- /dev/null
+++ b/media-libs/libtheora/libtheora-1.1_alpha1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libtheora/libtheora-1.1_alpha1.ebuild,v 1.1 2009/05/07 08:38:39 ssuominen Exp $
+
+EAPI=2
+inherit autotools eutils flag-o-matic
+
+DESCRIPTION="The Theora Video Compression Codec"
+HOMEPAGE="http://www.theora.org"
+SRC_URI="http://downloads.xiph.org/releases/theora/${P/_}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc encode examples"
+
+RDEPEND="media-libs/libogg
+	encode? ( media-libs/libvorbis )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	dev-util/pkgconfig"
+
+VARTEXFONTS=${T}/fonts
+S=${WORKDIR}/${P/_}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.0_beta2-flags.patch
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_configure() {
+	use x86 && filter-flags -fforce-addr -frename-registers #200549
+	use doc || export ac_cv_prog_HAVE_DOXYGEN="false"
+
+	# Don't build specs even with doc enabled, just a few people would need
+	# it and causes sandbox violations.
+	export ac_cv_prog_HAVE_PDFLATEX="false"
+
+	econf \
+		--disable-dependency-tracking \
+		--disable-sdltest \
+		$(use_enable encode) \
+		--disable-examples
+}
+
+src_install() {
+	emake DESTDIR="${D}" docdir=/usr/share/doc/${PF} \
+		install || die "emake install failed"
+	dodoc AUTHORS CHANGES README
+	prepalldocs
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.[ch]
+	fi
+}