version bump

(Portage version: 2.1.4_rc4)

1 files changed, 63 insertions, 0 deletions

diff --git a/media-libs/libcaca/libcaca-0.99_beta13.ebuild b/media-libs/libcaca/libcaca-0.99_beta13.ebuild
new file mode 100644
index 000000000000..ea8fc5f6d648
--- /dev/null
+++ b/media-libs/libcaca/libcaca-0.99_beta13.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libcaca/libcaca-0.99_beta13.ebuild,v 1.1 2007/12/02 16:22:57 aballier Exp $
+
+inherit eutils autotools libtool
+
+MY_P="${P/_beta/.beta}"
+
+DESCRIPTION="A library that creates colored ASCII-art graphics"
+HOMEPAGE="http://libcaca.zoy.org/"
+SRC_URI="http://libcaca.zoy.org/files/${MY_P}.tar.gz"
+
+LICENSE="WTFPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc imlib mono ncurses nocxx opengl ruby slang X"
+
+RDEPEND="ncurses? ( >=sys-libs/ncurses-5.3 )
+	slang? ( =sys-libs/slang-1.4* )
+	imlib? ( media-libs/imlib2 )
+	X? ( x11-libs/libX11 x11-libs/libXt )
+	opengl? ( virtual/opengl virtual/glut )
+	mono? ( dev-lang/mono )
+	ruby? ( virtual/ruby )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen
+		virtual/latex-base )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${PN}-0.99_beta4-deoptimise.patch"
+
+	eautoreconf
+	elibtoolize
+}
+
+src_compile() {
+	# temp font fix #44128
+	export VARTEXFONTS="${T}/fonts"
+
+	econf \
+		$(use_enable doc) \
+		$(use_enable ncurses) \
+		$(use_enable slang) \
+		$(use_enable imlib imlib2) \
+		$(use_enable X x11) $(use_with X x) --x-libraries=/usr/$(get_libdir) \
+		$(use_enable opengl) \
+		$(use_enable !nocxx cxx) \
+		$(use_enable mono csharp) \
+		$(use_enable ruby) \
+		|| die "econf failed"
+	emake || die "emake failed"
+	unset VARTEXFONTS
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS BUGS ChangeLog NEWS NOTES README TODO
+}