Version bump, testsuite now pass, bug #448838.

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key C6085806)

3 files changed, 67 insertions, 6 deletions

diff --git a/media-libs/harfbuzz/ChangeLog b/media-libs/harfbuzz/ChangeLog
index 71ed08d24aec..3648ffc45d84 100644
--- a/media-libs/harfbuzz/ChangeLog
+++ b/media-libs/harfbuzz/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/harfbuzz
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/ChangeLog,v 1.21 2013/01/06 09:49:00 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/ChangeLog,v 1.22 2013/01/07 22:28:11 eva Exp $
+
+*harfbuzz-0.9.10 (07 Jan 2013)
+
+  07 Jan 2013; Gilles Dartiguelongue <eva@gentoo.org> +harfbuzz-0.9.10.ebuild,
+  harfbuzz-9999.ebuild:
+  Version bump, testsuite now pass, bug #448838.
 
   06 Jan 2013; Agostino Sarubbo <ago@gentoo.org> harfbuzz-0.9.9.ebuild:
   Add ~sparc, wrt bug #449220
diff --git a/media-libs/harfbuzz/harfbuzz-0.9.10.ebuild b/media-libs/harfbuzz/harfbuzz-0.9.10.ebuild
new file mode 100644
index 000000000000..485b6e780111
--- /dev/null
+++ b/media-libs/harfbuzz/harfbuzz-0.9.10.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/harfbuzz-0.9.10.ebuild,v 1.1 2013/01/07 22:28:11 eva Exp $
+
+EAPI=5
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/harfbuzz"
+[[ ${PV} == 9999 ]] && inherit git-2 autotools
+
+inherit eutils libtool
+
+DESCRIPTION="An OpenType text shaping engine"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/HarfBuzz"
+[[ ${PV} == 9999 ]] || SRC_URI="http://www.freedesktop.org/software/${PN}/release/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris"
+IUSE="static-libs"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/icu
+	media-gfx/graphite2
+	media-libs/freetype:2
+	x11-libs/cairo
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		# on Darwin we need to link with g++, like automake defaults to,
+		# but overridden by upstream because on Linux this is not
+		# necessary, bug #449126
+		sed -i \
+			-e 's/\<LINK\>/CXXLINK/' \
+			src/Makefile.am || die
+		sed -i \
+			-e '/libharfbuzz_la_LINK = /s/\<LINK\>/CXXLINK/' \
+			src/Makefile.in || die
+	fi
+	[[ ${PV} == 9999 ]] && eautoreconf
+	elibtoolize  # for building a shared library on x64-solaris
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}
diff --git a/media-libs/harfbuzz/harfbuzz-9999.ebuild b/media-libs/harfbuzz/harfbuzz-9999.ebuild
index 133c0988dfad..509fb6455e83 100644
--- a/media-libs/harfbuzz/harfbuzz-9999.ebuild
+++ b/media-libs/harfbuzz/harfbuzz-9999.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/harfbuzz-9999.ebuild,v 1.7 2012/12/31 21:12:01 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/harfbuzz-9999.ebuild,v 1.8 2013/01/07 22:28:11 eva Exp $
 
 EAPI=5
 
@@ -16,7 +16,7 @@ HOMEPAGE="http://www.freedesktop.org/wiki/Software/HarfBuzz"
 LICENSE="MIT"
 SLOT="0"
 [[ ${PV} == 9999 ]] || \
-KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris"
 IUSE="static-libs"
 
 RDEPEND="
@@ -29,8 +29,6 @@ RDEPEND="
 DEPEND="${RDEPEND}
 	virtual/pkgconfig
 "
-# needed for autoreconf
-[[ ${PV} == 9999 ]] && DEPEND+=" dev-util/gtk-doc-am"
 
 src_prepare() {
 	if [[ ${CHOST} == *-darwin* ]] ; then