Version bump. Bug #511074

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 09BF4F54C2BA7F3C!)

2 files changed, 69 insertions, 1 deletions

diff --git a/media-gfx/feh/ChangeLog b/media-gfx/feh/ChangeLog
index 031fe234af3a..953b38b12d5f 100644
--- a/media-gfx/feh/ChangeLog
+++ b/media-gfx/feh/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/feh
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/feh/ChangeLog,v 1.144 2014/04/28 02:28:19 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/feh/ChangeLog,v 1.145 2014/05/24 12:04:04 hwoarang Exp $
+
+*feh-2.12 (24 May 2014)
+
+  24 May 2014; Markos Chandras <hwoarang@gentoo.org> +feh-2.12.ebuild:
+  Version bump. Bug #511074
 
 *feh-2.11 (28 Apr 2014)
 
diff --git a/media-gfx/feh/feh-2.12.ebuild b/media-gfx/feh/feh-2.12.ebuild
new file mode 100644
index 000000000000..7a76584a20b3
--- /dev/null
+++ b/media-gfx/feh/feh-2.12.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/feh/feh-2.12.ebuild,v 1.1 2014/05/24 12:04:04 hwoarang Exp $
+
+EAPI=5
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A fast, lightweight imageviewer using imlib2"
+HOMEPAGE="http://feh.finalrewind.org/"
+SRC_URI="http://feh.finalrewind.org/${P}.tar.bz2"
+
+LICENSE="feh"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~x86"
+IUSE="debug curl exif test xinerama"
+
+COMMON_DEPEND=">=media-libs/giblib-1.2.4
+	media-libs/imlib2
+	>=media-libs/libpng-1.2:0=
+	x11-libs/libX11
+	curl? ( net-misc/curl )
+	exif? ( media-libs/libexif )
+	xinerama? ( x11-libs/libXinerama )"
+RDEPEND="${COMMON_DEPEND}
+	virtual/jpeg:0"
+DEPEND="${COMMON_DEPEND}
+	x11-libs/libXt
+	x11-proto/xproto
+	test? (
+		>=dev-lang/perl-5.10
+		dev-perl/Test-Command
+		)"
+
+pkg_setup() {
+	use_feh() { usex $1 1 0; }
+
+	fehopts=(
+		DESTDIR="${D}"
+		PREFIX=/usr
+		doc_dir='${main_dir}'/share/doc/${PF}
+		example_dir='${main_dir}'/share/doc/${PF}/examples
+		curl=$(use_feh curl)
+		debug=$(use_feh debug)
+		xinerama=$(use_feh xinerama)
+		exif=$(use_feh exif)
+		)
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.6.2-debug-cflags.patch
+	# fix desktop file
+	sed -i -e "s:^Icon=.*:Icon=/usr/share/feh/images/logo.svg:" \
+		share/applications/${PN}.pre || die
+}
+
+src_compile() {
+	tc-export CC
+	emake "${fehopts[@]}"
+}
+
+src_install() {
+	emake "${fehopts[@]}" install
+}