Version bump, add openexr use flag (bug #499708).

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

4 files changed, 177 insertions, 5 deletions

diff --git a/media-gfx/darktable/ChangeLog b/media-gfx/darktable/ChangeLog
index dee8c5c9a890..3d7c60e7a754 100644
--- a/media-gfx/darktable/ChangeLog
+++ b/media-gfx/darktable/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/darktable
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.53 2014/01/21 20:35:00 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.54 2014/02/11 05:43:49 radhermit Exp $
+
+*darktable-1.4.1 (11 Feb 2014)
+
+  11 Feb 2014; Tim Harder <radhermit@gentoo.org> +darktable-1.4.1.ebuild,
+  darktable-9999.ebuild, +files/darktable-1.4.1-automagic-openexr.patch:
+  Version bump, add openexr use flag (bug #499708).
 
 *darktable-1.4 (21 Jan 2014)
 
diff --git a/media-gfx/darktable/darktable-1.4.1.ebuild b/media-gfx/darktable/darktable-1.4.1.ebuild
new file mode 100644
index 000000000000..0a237edccb4d
--- /dev/null
+++ b/media-gfx/darktable/darktable-1.4.1.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-1.4.1.ebuild,v 1.1 2014/02/11 05:43:49 radhermit Exp $
+
+EAPI=5
+
+inherit cmake-utils toolchain-funcs gnome2-utils fdo-mime pax-utils eutils
+
+DESCRIPTION="A virtual lighttable and darkroom for photographers"
+HOMEPAGE="http://www.darktable.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	doc? ( mirror://sourceforge/${PN}/${PV}/${PN}-usermanual.pdf -> ${PN}-usermanual-${PV}.pdf )"
+
+LICENSE="GPL-3 CC-BY-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+LANGS=" cs da de el es fr it ja nl pl pt_BR pt_PT ru sq sv uk"
+# TODO add lua once dev-lang/lua-5.2 is unmasked
+IUSE="colord doc flickr geo gnome-keyring gphoto2 graphicsmagick jpeg2k kde
+nls opencl openmp openexr pax_kernel +rawspeed +slideshow +squish web-services webp
+${LANGS// / linguas_}"
+
+CDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.28:2
+	dev-libs/libxml2:2
+	gnome-base/librsvg:2
+	media-gfx/exiv2:0=[xmp]
+	media-libs/lcms:2
+	>=media-libs/lensfun-0.2.3
+	media-libs/libpng:0=
+	media-libs/tiff:0
+	net-misc/curl
+	virtual/jpeg
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:2
+	x11-libs/pango
+	colord? ( x11-misc/colord:0= )
+	flickr? ( media-libs/flickcurl )
+	geo? ( net-libs/libsoup:2.4 )
+	gnome-keyring? ( gnome-base/gnome-keyring )
+	gphoto2? ( media-libs/libgphoto2:= )
+	graphicsmagick? ( media-gfx/graphicsmagick )
+	jpeg2k? ( media-libs/openjpeg:0 )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	slideshow? (
+		media-libs/libsdl
+		virtual/glu
+		virtual/opengl
+	)
+	web-services? ( dev-libs/json-glib )
+	webp? ( media-libs/libwebp:0= )"
+RDEPEND="${CDEPEND}
+	kde? ( kde-base/kwalletd )"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+PATCHES=( "${FILESDIR}"/${P}-automagic-openexr.patch )
+
+pkg_pretend() {
+	if use openmp ; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	sed -e "s:\(/share/doc/\)darktable:\1${PF}:" \
+		-e "s:LICENSE::" \
+		-i doc/CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_use colord COLORD)
+		$(cmake-utils_use_use flickr FLICKR)
+		$(cmake-utils_use_use geo GEO)
+		$(cmake-utils_use_use gnome-keyring GNOME_KEYRING)
+		$(cmake-utils_use_use gphoto2 CAMERA_SUPPORT)
+		$(cmake-utils_use_use graphicsmagick GRAPHICSMAGICK)
+		$(cmake-utils_use_use jpeg2k OPENJPEG)
+		$(cmake-utils_use_use nls NLS)
+		$(cmake-utils_use_use opencl OPENCL)
+		$(cmake-utils_use_use openexr OPENEXR)
+		$(cmake-utils_use_use openmp OPENMP)
+		$(cmake-utils_use !rawspeed DONT_USE_RAWSPEED)
+		$(cmake-utils_use_use squish SQUISH)
+		$(cmake-utils_use_build slideshow SLIDESHOW)
+		$(cmake-utils_use_use web-services GLIBJSON)
+		$(cmake-utils_use_use webp WEBP)
+		-DUSE_LUA=OFF
+		-DCUSTOM_CFLAGS=ON
+		-DINSTALL_IOP_EXPERIMENTAL=ON
+		-DINSTALL_IOP_LEGACY=ON
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	use doc && dodoc "${DISTDIR}"/${PN}-usermanual-${PV}.pdf
+
+	for lang in ${LANGS} ; do
+		use linguas_${lang} || rm -r "${ED}"/usr/share/locale/${lang}
+	done
+
+	if use pax_kernel && use opencl ; then
+		pax-mark Cm "${ED}"/usr/bin/${PN} || die
+		eqawarn "USE=pax_kernel is set meaning that ${PN} will be run"
+		eqawarn "under a PaX enabled kernel. To do so, the ${PN} binary"
+		eqawarn "must be modified and this *may* lead to breakage! If"
+		eqawarn "you suspect that ${PN} is broken by this modification,"
+		eqawarn "please open a bug."
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
diff --git a/media-gfx/darktable/darktable-9999.ebuild b/media-gfx/darktable/darktable-9999.ebuild
index 8a4b6912a895..bb590a9c922a 100644
--- a/media-gfx/darktable/darktable-9999.ebuild
+++ b/media-gfx/darktable/darktable-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild,v 1.12 2014/01/21 20:35:00 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild,v 1.13 2014/02/11 05:43:49 radhermit Exp $
 
 EAPI=5
 
@@ -10,11 +10,9 @@ EGIT_REPO_URI="git://github.com/darktable-org/darktable.git"
 
 DESCRIPTION="A virtual lighttable and darkroom for photographers"
 HOMEPAGE="http://www.darktable.org/"
-SRC_URI=""
 
 LICENSE="GPL-3 CC-BY-3.0"
 SLOT="0"
-KEYWORDS=""
 LANGS=" cs da de el es fr it ja nl pl pt_BR pt_PT ru sq sv uk"
 # TODO add lua once dev-lang/lua-5.2 is unmasked
 IUSE="colord doc flickr geo gnome-keyring gphoto2 graphicsmagick jpeg2k kde
@@ -70,7 +68,7 @@ src_prepare() {
 		-e "s:LICENSE::" \
 		-i doc/CMakeLists.txt || die
 
-	epatch_user
+	cmake-utils_src_prepare
 }
 
 src_configure() {
diff --git a/media-gfx/darktable/files/darktable-1.4.1-automagic-openexr.patch b/media-gfx/darktable/files/darktable-1.4.1-automagic-openexr.patch
new file mode 100644
index 000000000000..f41c0b00d0f1
--- /dev/null
+++ b/media-gfx/darktable/files/darktable-1.4.1-automagic-openexr.patch
@@ -0,0 +1,35 @@
+--- darktable-1.4.1/CMakeLists.txt
++++ darktable-1.4.1/CMakeLists.txt
+@@ -26,6 +26,7 @@
+ option(BINARY_PACKAGE_BUILD "Sets march optimization to generic" OFF)
+ option(APRIL_FOOLS "Add the \"file manager\" (a shell) to lighttable mode" OFF)
+ option(USE_XMLLINT "Run xmllint to test if darktableconfig.xml is valid" ON)
++option(USE_OPENEXR "Enable OpenEXR support" ON)
+ option(USE_OPENJPEG "Enable JPEG 2000 support" ON)
+ option(USE_WEBP "Enable WebP export support" ON)
+ option(BUILD_CMSTEST "Build a test program to check your system's color management setup" OFF)
+--- darktable-1.4.1/src/CMakeLists.txt
++++ darktable-1.4.1/src/CMakeLists.txt
+@@ -152,13 +152,15 @@
+   add_definitions(${INOTIFY_DEFINITIONS})
+ endif(INOTIFY_FOUND)
+ 
+-find_package(OpenEXR)
+-if(OPENEXR_FOUND)
+-  include_directories(${OpenEXR_INCLUDE_DIRS})
+-  list(APPEND LIBS ${OpenEXR_LIBRARIES})
+-  add_definitions(${OpenEXR_DEFINITIONS})
+-  list(APPEND SOURCES "common/imageio_exr.cc")
+-endif(OPENEXR_FOUND)
++if(USE_OPENEXR)
++  find_package(OpenEXR)
++  if(OPENEXR_FOUND)
++    include_directories(${OpenEXR_INCLUDE_DIRS})
++    list(APPEND LIBS ${OpenEXR_LIBRARIES})
++    add_definitions(${OpenEXR_DEFINITIONS})
++    list(APPEND SOURCES "common/imageio_exr.cc")
++  endif(OPENEXR_FOUND)
++endif(USE_OPENEXR)
+ 
+ find_package(WebP 0.3.0)
+ if(WEBP_FOUND)