KDE 4.8.4 version bump

(Portage version: 2.2.0_alpha110/cvs/Linux x86_64, RepoMan options: --force)

1 files changed, 64 insertions, 0 deletions

diff --git a/kde-base/kwin/kwin-4.8.4.ebuild b/kde-base/kwin/kwin-4.8.4.ebuild
new file mode 100644
index 000000000000..6a22e87dc292
--- /dev/null
+++ b/kde-base/kwin/kwin-4.8.4.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kwin/kwin-4.8.4.ebuild,v 1.1 2012/06/21 21:54:50 dilfridge Exp $
+
+EAPI=4
+
+KMNAME="kde-workspace"
+OPENGL_REQUIRED="always"
+inherit flag-o-matic kde4-meta
+
+DESCRIPTION="KDE window manager"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug gles opengl"
+
+COMMONDEPEND="
+	$(add_kdebase_dep kactivities)
+	$(add_kdebase_dep kdelibs opengl)
+	$(add_kdebase_dep kephal)
+	$(add_kdebase_dep libkworkspace)
+	$(add_kdebase_dep liboxygenstyle)
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXfixes
+	>=x11-libs/libXrandr-1.2.1
+	x11-libs/libXrender
+	opengl? ( >=media-libs/mesa-7.10 )
+	gles? (
+		|| (  ( >=media-libs/mesa-7.10[egl(+),gles] <media-libs/mesa-7.12[egl(+),gles] )
+			>=media-libs/mesa-7.12[egl(+),gles2] )
+	)
+"
+DEPEND="${COMMONDEPEND}
+	x11-proto/compositeproto
+	x11-proto/damageproto
+	x11-proto/fixesproto
+	x11-proto/randrproto
+	x11-proto/renderproto
+"
+RDEPEND="${COMMONDEPEND}
+	x11-apps/scripts
+"
+
+KMEXTRACTONLY="
+	ksmserver/
+	libs/kephal/
+	libs/oxygen/
+"
+
+# you need one of these
+REQUIRED_USE="!opengl? ( gles ) !gles? ( opengl )"
+
+src_configure() {
+	# FIXME Remove when activity API moved away from libkworkspace
+	append-cppflags "-I${EPREFIX}/usr/include/kworkspace"
+
+	mycmakeargs=(
+		$(cmake-utils_use_with gles OpenGLES)
+		$(cmake-utils_use gles KWIN_BUILD_WITH_OPENGLES)
+		$(cmake-utils_use_with opengl OpenGL)
+		-DWITH_X11_Xcomposite=ON
+	)
+
+	kde4-meta_src_configure
+}