Version bump KDE SC 4.8.3

(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

2 files changed, 76 insertions, 1 deletions

diff --git a/kde-base/kdepimlibs/ChangeLog b/kde-base/kdepimlibs/ChangeLog
index 0849a8e13208..e1df0e8eddbc 100644
--- a/kde-base/kdepimlibs/ChangeLog
+++ b/kde-base/kdepimlibs/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kdepimlibs
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.142 2012/04/18 18:54:59 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.143 2012/05/03 20:07:49 johu Exp $
+
+*kdepimlibs-4.8.3 (03 May 2012)
+
+  03 May 2012; Johannes Huber <johu@gentoo.org> +kdepimlibs-4.8.3.ebuild:
+  Version bump KDE SC 4.8.3
 
   18 Apr 2012; Markus Meier <maekke@gentoo.org> kdepimlibs-4.8.1.ebuild:
   x86 stable, bug #409403
diff --git a/kde-base/kdepimlibs/kdepimlibs-4.8.3.ebuild b/kde-base/kdepimlibs/kdepimlibs-4.8.3.ebuild
new file mode 100644
index 000000000000..c941f2e265d1
--- /dev/null
+++ b/kde-base/kdepimlibs/kdepimlibs-4.8.3.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/kdepimlibs-4.8.3.ebuild,v 1.1 2012/05/03 20:07:49 johu Exp $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+CPPUNIT_REQUIRED="optional"
+KDE_SCM="git"
+inherit kde4-base
+
+DESCRIPTION="Common library for KDE PIM apps."
+HOMEPAGE="http://www.kde.org/"
+
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+LICENSE="LGPL-2.1"
+IUSE="debug ldap prison semantic-desktop"
+
+# some akonadi tests timeout, that probaly needs more work as its ~700 tests
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=app-crypt/gpgme-1.1.6
+	dev-libs/libgpg-error
+	>=dev-libs/libical-0.43
+	dev-libs/cyrus-sasl
+	$(add_kdebase_dep kdelibs 'semantic-desktop=')
+	prison? ( media-libs/prison )
+	semantic-desktop? (
+		>=app-office/akonadi-server-1.7.0
+		media-libs/phonon
+		x11-misc/shared-mime-info
+	)
+	ldap? ( net-nds/openldap )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.35.0-r5
+"
+RDEPEND="${COMMON_DEPEND}"
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	# Disable hardcoded checks
+	sed -r -e '/find_package\((Akonadi|SharedDesktopOntologies|Soprano|Nepomuk)/{/macro_optional_/!s/find/macro_optional_&/}' \
+		-e '/macro_log_feature\((Akonadi|SHAREDDESKTOPONTOLOGIES|Soprano|Nepomuk)_FOUND/s/ TRUE / FALSE /' \
+		-e '/add_subdirectory\((akonadi|mailtransport)/{/macro_optional_/!s/add/macro_optional_&/}' \
+		-i CMakeLists.txt || die
+	if ! use semantic-desktop; then
+		sed -e '/include(SopranoAddOntology)/s/^/#DISABLED /' \
+			-i CMakeLists.txt || die
+		# More reliable than -DBUILD_akonadi=OFF
+		rm -r akonadi mailtransport || die
+	fi
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build handbook doc)
+		$(cmake-utils_use_with ldap)
+		$(cmake-utils_use_with semantic-desktop Akonadi)
+		$(cmake-utils_use_with semantic-desktop SharedDesktopOntologies)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		$(cmake-utils_use !semantic-desktop KALARM_USE_KRESOURCES)
+		$(cmake-utils_use_with prison)
+	)
+
+	kde4-base_src_configure
+}