Version bump KDE SC 4.9.2

(Portage version: 2.2.0_alpha134/cvs/Linux x86_64)

2 files changed, 56 insertions, 1 deletions

diff --git a/kde-base/cantor/ChangeLog b/kde-base/cantor/ChangeLog
index 544e1f495c01..731a1f876af4 100644
--- a/kde-base/cantor/ChangeLog
+++ b/kde-base/cantor/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/cantor
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/ChangeLog,v 1.83 2012/09/21 09:32:36 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/ChangeLog,v 1.84 2012/10/02 18:12:01 johu Exp $
+
+*cantor-4.9.2 (02 Oct 2012)
+
+  02 Oct 2012; Johannes Huber <johu@gentoo.org> +cantor-4.9.2.ebuild:
+  Version bump KDE SC 4.9.2
 
   21 Sep 2012; Johannes Huber <johu@gentoo.org> -cantor-4.9.0.ebuild:
   Remove KDE SC 4.9.0
diff --git a/kde-base/cantor/cantor-4.9.2.ebuild b/kde-base/cantor/cantor-4.9.2.ebuild
new file mode 100644
index 000000000000..e9e731eae3ab
--- /dev/null
+++ b/kde-base/cantor/cantor-4.9.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/cantor-4.9.2.ebuild,v 1.1 2012/10/02 18:12:01 johu Exp $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+inherit kde4-base
+
+DESCRIPTION="KDE4 interface for doing mathematics and scientific computing"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="analitza debug postscript qalculate +R"
+
+# TODO Add Sage Mathematics Software backend (http://www.sagemath.org)
+RDEPEND="
+	analitza? ( $(add_kdebase_dep analitza) )
+	qalculate? (
+		sci-libs/cln
+		sci-libs/libqalculate
+	)
+	postscript? ( app-text/libspectre )
+	R? ( dev-lang/R )
+	x11-libs/qt-xmlpatterns:4
+"
+DEPEND="${RDEPEND}
+	>=dev-cpp/eigen-2.0.3:2
+"
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with analitza)
+		$(cmake-utils_use_with postscript LibSpectre)
+		$(cmake-utils_use_with qalculate)
+		$(cmake-utils_use_with R)
+	)
+	kde4-base_src_configure
+}
+
+pkg_postinst() {
+	kde4-base_pkg_postinst
+
+	if ! use analitza && ! use qalculate && ! use R; then
+		echo
+		ewarn "You have decided to build ${PN} with no backend."
+		ewarn "To have this application functional, please do one of below:"
+		ewarn "    # emerge -va1 '='${CATEGORY}/${P} with 'analitza', 'qalculate' or 'R' USE flag enabled"
+		ewarn "    # emerge -vaDu sci-mathematics/maxima"
+		echo
+	fi
+}